How to transfer the data of columns to rows (with awk)?

问题

I have a file like this:

n A B C D 
1 01 02 01 01
2 02 02 01 01

and I want to transfer the columns by rows, so the output should be like this:

I have wrote this command:

awk '{ for (i=1;i<=NF;i++ ) printf $i " " }' file.txt > out-file.txt

the problem is that this command put everything on one line! so the output is like this:

n 1 2 A 01 02 B 02 02 C 01 01 D 01 01

回答1:

This might work:

awk '{
       for (f = 1; f <= NF; f++) { a[NR, f] = $f } 
     }
     NF > nf { nf = NF }
     END {
       for (f = 1; f <= nf; f++) {
           for (r = 1; r <= NR; r++) {
               printf a[r, f] (r==NR ? RS : FS)
           }
       }
    }' YOURINPUT

See it in action @ Ideone.

回答2:

Save this script as transpose.awk and chmod u+x transpose.awk. It's a modification of Tim Sherwood's transpose.

#!/usr/bin/gawk -f

BEGIN {
    max_x =0;
    max_y =0;
}

{
    max_y++;
    for( i=1; i<=NF; i++ )
    {
        if (i>max_x) max_x=i;
        A[i,max_y] = $i;
    }
}

END {
    for ( x=1; x<=max_x; x++ )
    {
        for ( y=1; y<=max_y; y++ )
        {
            if ( (x,y) in A ) printf "%s",A[x,y];
            if ( y!=max_y ) printf " ";
        }
        printf "\n";
    }
}

Example:

$ ./transpose.awk example
n 1 2
A 01 02
B 02 02
C 01 01
D 01 01

回答3:

It would be easier to use rs:

$ cat /tmp/a
n A B C D
1 01 02 01 01
2 02 02 01 01
$ rs -c' ' -C' ' -T</tmp/a
n 1 2
A 01 02
B 02 02
C 01 01
D 01 01

-c changes the input column separator, -C changes the output column separator, and -T transposes rows and columns.

回答4:

Well, without awk we can do this with cat:

for x in `cat filename`
do
echo $x
done

With this script the result will emerge in cols.

回答5:

Here is a different solution, which involve only one for loop at the end:

{ for (i=1; i<=NF; i++) col[i] = col[i] " " $i }
END { 
    for (i=1; i<=NF; i++) { 
        sub(/^ /, "", col[i]); 
        print col[i] 
    } 
}

Discussion

This solution uses a single-dimension array col, which stores the value for the whole column. col[1] is the first column.
For every line, we append the column to col[i]. Because we blindly append, the col[i] value will contain a leading space.
At the end, the sub() function removes the leading white space before printing out the column (now a row)

来源：https://stackoverflow.com/questions/9534744/how-to-transfer-the-data-of-columns-to-rows-with-awk

标签

Linux

awk

rows