Another CoffeeScript Error

问题

Hey, I am Just Learning CoffeeScript and I Keep getting Errors. Here is my code:

Db   = require('./lib/mongodb').Db
ObjectID = require('./lib/mongodb').ObjectID
Server   = require('./lib/mongodb').Server

class UserDataProvider
    constructor = (host,port)->
        this.db = new Db( 'test' , new Server(host ,port,{}))
    getCollection = (callback) ->
        this.db.collection 'data',(error,data)->
            if error then callback(error)
            else callback(data)
    findAll = (callback) ->
        this.getCollection (error,data)->
            if error then callback error
            else
                data.find (error, cursor) ->
                    if error then callback error
                    else
                        cursor.toArray (error, results)->
                            if error then callback error
                            else callback(null,results)
    findById = (id,callback)->
        this.getCollection (error, data)->
          if error then callback error
          else
            data.findOne { _id: id} , (error, result)->
              if error then callback error
              else callback(null, result)
    save = (data, callback)->
        this.getCollection (error, collection)->
            if error then callback error
            else
                if typeof(data.length) is "undefined"
                then data = [data]

                collection.insert data ()->
                    callback null, data

exports.UserDataProvider = UserDataProvider

When I try to use userdataprovider.save( ?? BLAH BLAH BLAH ??) // I already instantiated it.

I get this error:

TypeError: Object #<UserDataProvider> has no method 'save'
    at Object.<anonymous> (/home/akshay/dev/statServer/app.js:8:15)
    at param (/usr/local/lib/node/.npm/connect/0.5.10/package/lib/connect/middleware/router.js:146:21)
    at param (/usr/local/lib/node/.npm/connect/0.5.10/package/lib/connect/middleware/router.js:157:15)
    at pass (/usr/local/lib/node/.npm/connect/0.5.10/package/lib/connect/middleware/router.js:162:10)
    at Object.router [as handle] (/usr/local/lib/node/.npm/connect/0.5.10/package/lib/connect/middleware/router.js:168:6)
    at next (/usr/local/lib/node/.npm/connect/0.5.10/package/lib/connect/index.js:218:15)
    at Object.handle (/usr/local/lib/node/.npm/express/1.0.7/package/lib/express/server.js:65:5)
    at next (/usr/local/lib/node/.npm/connect/0.5.10/package/lib/connect/index.js:218:15)
    at Server.handle (/usr/local/lib/node/.npm/connect/0.5.10/package/lib/connect/index.js:231:3)
    at Server.emit (events.js:45:17)

If it matters, I am using Expressjs and Nodejs with Native MongoDB Driver

回答1:

The problem is that you're using = instead of : to define instance-level methods.

CoffeeScript's class construct is an odd hybrid of object and function. Code within the class body runs immediately—for instance,

class UserDataProvider
    a = 'foo'
    console.log a

prints foo. But when you use the object syntax key: value, you define properties of the prototype (except in the case of the special keyword constructor):

class UserDataProvider
  a: 'foo'

(new UserDataProvider).a   # 'foo'

This might seem odd, but it allows you to run one-time static initialization code which can be useful, including private variables that can only be seen by methods defined within the class:

class UserDataProvider
    secretPassword = Math.random()
    getHash: -> hash(secretPassword)

Long story short: Use : instead of = when defining instance properties. (For static properties, @a = b and @a: b are equivalent; both set UserDataProvider.a to b.)

来源：https://stackoverflow.com/questions/5124383/another-coffeescript-error

标签

javascript

compiler-errors

coffeescript