Ignore failure in pipeline build step

问题

With jenkins build flow plugin this was possible:

ignore(FAILURE){
    build( "system-check-flow" )
}

How to do this with Declarative Pipeline syntax?

回答1:

To ignore a failed step in declarative pipeline you basically have two options:

Use script step and try-catch block (similar to previous proposition by R_K but in declarative style)

stage('someStage') {
    steps {
        script {
            try {
                build job: 'system-check-flow'
            } catch (err) {
                echo err
            }
        }
        echo currentBuild.result
    }
}

Use catchError

stage('someStage') {
    steps {
        catchError {
            build job: 'system-check-flow'
        }
        echo currentBuild.result
    }
}

In both cases the build won't be aborted upon exception in build job: 'system-check-flow'. In both cases the echo step (and any other following) will be executed.

But there's one important difference between these two options. In first case if the try section raises an exception the overall build status won't be changed (so echo currentBuild.result => SUCCESS). In the second case you overall build will fail (so echo currentBuild.result => FAILURE).

This is important, because you can always fail the overall build in first case (by setting currentBuild.result = 'FAILURE') but you can't repair build in second option (currentBuild.result = 'SUCCESS' won't work).

回答2:

In addition to simply making the stage pass, it is now also possible to fail the stage, but continue the pipeline and pass the build:

pipeline {
    agent any
    stages {
        stage('1') {
            steps {
                sh 'exit 0'
            }
        }
        stage('2') {
            steps {
                catchError(buildResult: 'SUCCESS', stageResult: 'FAILURE') {
                    sh "exit 1"
                }
            }
        }
        stage('3') {
            steps {
                sh 'exit 0'
            }
        }
    }
}

In the example above, all stages will execute, the pipeline will be successful, but stage 2 will show as failed:

As you might have guessed, you can freely choose the buildResult and stageResult, in case you want it to be unstable or anything else. You can even fail the build and continue the execution of the pipeline.

Just make sure your Jenkins is up to date, since this feature is only available since "Pipeline: Basic Steps" 2.16 (May 14, 2019). Before that, catchError is still available but without parameters:

        steps {
            catchError {
                sh "exit 1"
            }
        }

回答3:

I was looking for an answer for a long time and I found a hack for it! I put the try/catch block on the whole stage:

 try {
   stage('some-stage') {
         //do something
   }
 } catch (Exception e) {
    echo "Stage failed, but we continue"  
 }
 try {
   stage("some-other-stage") {  // do something }
 } catch (Exception e) {
    echo "Stage failed, but we still continue"
 }

As result you will get something like this:

This is still not ideal, but it gives the necessary results.

回答4:

In recent versions it's possible to pass propogate=false option to build step.

link: https://jenkins.io/doc/pipeline/steps/pipeline-build-step/

example: build job:"jobName", propagate:false

回答5:

For my decalartive pipeline I have found another solution:

stage('Deploy test')
 {
  steps
   {      
    bat returnStatus: true, script: 'sc stop Tomcat9'
    // The return value of the step will be the status code!
    // evaluate return status yourself, or ignore it
   }
 }

The same works for the sh command to execute scripts on Unix platforms.

The example ignores the return status, because the tomcat might be already stopped, because of a previously failed pipeline run.

回答6:

In the new pipeline, you can use try-catch to achieve this.

node{
   try{
      build job: 'system-check-flow'
   }    
   catch (err){
      echo "system-check-flow failed"
   }
   try{
      build job: 'job2'
   }    
   catch (err){
      echo "job2 failed"
   }
}

Here it will build the 'system-check-flow' job. If it fails it will catch the error, ignore, and then move on to build 'job2'

来源：https://stackoverflow.com/questions/44022775/ignore-failure-in-pipeline-build-step

标签

Jenkins

jenkins-pipeline