Merge cells doesn't work after locking and unlocking other cell

问题

I've got a sheet in which I'm trying to merge some cells based on CX cell value. CX cell is also dynamically locked/unlocked based on BX cell value. Although locking/unlocking works fine, I get 1004 error when I'm trying to merge cells with line: Range(Cells(Target.Row, i), Cells(Target.Row + Target.Value - 1, i)).Merge

While code is below.

Option Explicit

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)

    If Not Intersect(Target, Range("B14:B50")) Is Nothing And Sh.Name <> "Dane" Then
        Dim pass As String
        pass = "" 'set the password. Otherwise, protection/unprotection is done without a pass
        If Target.Cells.Count > 1 Then Exit Sub
        ActiveSheet.Unprotect pass
        If Target.Value = "Unlocked" Then
            Target.Offset(0, 1).Locked = False
        Else
            Target.Offset(0, 1).Value = 0
            Target.Offset(0, 1).Locked = True
        End If
        ActiveSheet.Protect pass
    End If
    
    If Not Intersect(Target, Range("C14:C50")) Is Nothing And Sh.Name <> "Dane" Then
        Dim i As Long
                
        Application.DisplayAlerts = False
        For i = 1 To 8 Step 1
            If i <> 6 And i <> 7 And Cells(Target.Row, i).MergeCells Then
                Cells(Target.Row, i).UnMerge
            End If
        Next i
        If Target.Value <> 0 Then
            For i = 1 To 8 Step 1
                If i <> 6 And i <> 7 Then
                    Range(Cells(Target.Row, i), Cells(Target.Row + Target.Value - 1, i)).Merge
                End If
            Next i
        End If
        Application.DisplayAlerts = True
    End If
    
End Sub

回答1:

Okay. So with @FaneDuru comments, I've been able to figure out the issue. Sheet protection was causing the problem, so I had to unprotect and reprotect sheet before for loops in second condition. Also, @FaneDuru advised to set EnableEvents = false there, to prevent any infinite loop issue. Below is the fixed code.

Option Explicit

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)

    If Not Intersect(Target, Range("B14:B50")) Is Nothing And Sh.Name <> "Dane" Then
        Dim pass As String
        pass = "" 'set the password. Otherwise, protection/unprotection is done without a pass
        If Target.Cells.Count > 1 Then Exit Sub
        ActiveSheet.Unprotect pass
        If Target.Value = "Unlocked" Then
            Target.Offset(0, 1).Locked = False
        Else
            Target.Offset(0, 1).Value = 0
            Target.Offset(0, 1).Locked = True
        End If
        ActiveSheet.Protect pass
    End If
    
    If Not Intersect(Target, Range("C14:C50")) Is Nothing And Sh.Name <> "Dane" Then
        Dim i As Long
                
        Application.DisplayAlerts = False
        Application.EnableEvents = False
        ActiveSheet.Unprotect pass
        For i = 1 To 8 Step 1
            If i <> 6 And i <> 7 And Cells(Target.Row, i).MergeCells Then
                Cells(Target.Row, i).UnMerge
            End If
        Next i
        If Target.Value <> 0 Then
            For i = 1 To 8 Step 1
                If i <> 6 And i <> 7 Then
                    Range(Cells(Target.Row, i), Cells(Target.Row + Target.Value - 1, i)).Merge
                End If
            Next i
        End If
        ActiveSheet.Protect pass
        Application.EnableEvents = True
        Application.DisplayAlerts = True

    End If
    
End Sub

However, I'm still wondering why I need to unprotect the sheet to edit unlocked range.

来源：https://stackoverflow.com/questions/64751127/merge-cells-doesnt-work-after-locking-and-unlocking-other-cell