Windows BAT命令-网络相关设置（IP、WLAN等）

一、基本常用命令

# 查看本地网卡接口信息
ipconfig /all

# ping(常用于测试网络连通性)
ping www.baidu.com

# 路由相关

# 1.查看路由表(其中0.0.0.0记录为默认路由配置)
route print

# 2.添加路由(如果添加-p参数可表示添加永久路由)
route add 192.168.1.0 maks 255.255.255.0 192.168.1.11

# 3.删除路由
route delete 192.168.1.0

# 4.跟踪路由
tracert www.baidu.com

# 地址解析（ip地址到mac地址的映射）
arp -a

# 网络配置（网络连接命令行配置接口）

# 导出本地网络连接配置信息
netsh interface ip dump > d:/netConfig.txt

# 导入网络配置
netsh exec d:/netConfig.txt

# 设置本地连接通过dhcp自动配置
netsh interface ip set address "本地连接" duhp

# 设置本地连接静态IP
netsh interface ip set address "本地连接" static 192.168.1.11 255.255.255.0 192.168.1.1

# 查看域名信息(可以得到域名对应的ip地址)
nslookup baidu.com

二、WLAN 无线连接配置文件列表

查询连接过的WLAN配置文件。

netsh wlan show profiles

三、WLAN 获取指定密码

获取某个链接密码。

netsh wlan show profiles name="WLAN名称" key=clear
测试：
netsh wlan show profiles name="TP-LINK" key=clear

四、WLAN 批量获取密码

保存为bat脚本。

@echo off
cls
color 0A
chcp 437 >nul
Echo *******************************************************************************
Echo           Current Network History List
Echo *******************************************************************************
for /f "tokens=1* delims=:" %%i in ('netsh wlan show profiles ^| findstr /c:"All User Profile"') do (
	call :GetPass %%j
)
Echo *******************************************************************************
Echo           Enter Any Key To Close ......
Echo *******************************************************************************
pause
goto :eof
:GetPass
Echo WIFI NAME : %*
for /f "delims=" %%a in ('netsh wlan show profile name^="%*" key^=clear ^| findstr /c:"Key Content"') do (
	Echo %%a
)
goto :eof

五、根据链接名称，设置IP地址、子网掩码、默认网关、DNS地址

先通过ipconfig /all，查找当前所有网络链接，name指定为要修改的网络链接，然后编辑对应的地址信息。

自动获取IP

@echo off
cls
color 0A
title 设置 WLAN 无线网络为 : IP自动获取模式
Echo *******************************************************************************
Echo           Update Current Network : WLAN-无线网络
Echo           修改目标 : 全自动获取
Echo           正在修改IP地址和DNS地址 , 请等待 ......
Echo *******************************************************************************
cmd /c netsh interface ip set address name="WLAN" source=dhcp
cmd /c netsh interface ip delete dns "WLAN" all
ipconfig /flushdns
ipconfig /all
Echo *******************************************************************************
Echo           修改成功 , 按任意键关闭 ......
Echo *******************************************************************************
Pause

指定IP地址

@echo off
cls
color 0A
Echo *******************************************************************************
Echo           Update Current Network : WLAN-无线网络
Echo           修改目标 : 1601办公室-TP-LINK_B8A9
Echo           正在修改IP地址和DNS地址 , 请等待 ......
Echo *******************************************************************************
cmd /c netsh interface ip set address name="WLAN" source=static addr=192.168.1.166 mask=255.255.255.0 gateway=192.168.1.1 gwmetric=1
cmd /c netsh interface ip set dns name="WLAN" source=static addr=202.100.199.8 validate=no
cmd /c netsh interface ip add dns name="WLAN" addr=202.100.192.68 index=2 validate=no
ipconfig /all
Echo *******************************************************************************
Echo           修改成功 , 按任意键关闭 ......
Echo *******************************************************************************
Pause

IP切换脚本

@echo off
cls
color 0A
title WLAN 无线网络 IP 切换脚本
:start

Echo *******************************************************************************
Echo 请选择 : 
Echo 1.1601-TP-Link_B8A9
Echo 2.1602-TP-Link
Echo 3.Auto-自动获取
Echo *******************************************************************************
set /p sLocal=请选择 : 
if %sLocal%==1 goto 1601
if %sLocal%==2 goto 1602
if %sLocal%==3 goto auto
cls
Echo 选择错误 , 请重新选择

goto start
:1601
Echo 正在设置无线网络连接为 : 1601-TP-Link_B8A9 固定IP : 192.168.1.166
cmd /c netsh interface ip set address name="WLAN" source=static addr=192.168.1.166 mask=255.255.255.0 gateway=192.168.1.1 gwmetric=1
cmd /c netsh interface ip set dns name="WLAN" source=static addr=202.100.199.8 validate=no
cmd /c netsh interface ip add dns name="WLAN" addr=202.100.192.68 index=2 validate=no
goto end

:1602
Echo 正在设置无线网络连接为 : 1602-TP-Link 固定IP : 192.168.0.166
cmd /c netsh interface ip set address name="WLAN" source=static addr=192.168.0.166 mask=255.255.255.0 gateway=192.168.0.1 gwmetric=1
cmd /c netsh interface ip set dns name="WLAN" source=static addr=202.100.199.8 validate=no
cmd /c netsh interface ip add dns name="WLAN" addr=202.100.192.68 index=2 validate=no
goto end

:auto
Echo 正在设置无线网络连接为 : Auto-自动获取 DHCP 模式
cmd /c netsh interface ip set address name="WLAN" source=dhcp
cmd /c netsh interface ip delete dns "WLAN" all
ipconfig /flushdns
goto end

:end
echo 设置成功
pause

来源：oschina

链接：https://my.oschina.net/discussjava/blog/4334085

标签

Any key