考虑结构预应力的坎贝尔图分析

这个分析相较之前的，就是多考虑了离心力产生的预应力。因为是否考虑预应力会导致模态分析的结果不同。

fini
/clear
!参数
pi = acos(-1)
ro = 47.5e-3
ri = 16.5e-3
t = 0.8e-3
w = 120*2*pi

/prep7
et,1,181
r,1,zh

!材料：铝
mp,ex,,7.2e+10
mp,nuxy,,.3
mp,dens,,2800.

!划分网格
esize,0.0025
cyl4,,,ri,0,ro,360
amesh,all

!边界条件
lsel,,,,5,8
dl,all,1,all
allsel
fini

!预应力模态分析
nbstep = 5 !步数
dw = w/(nbstep-1) !步长
*dim,spins,,nbstep !行数为nbstep,数组名为spins
*vfill,spins,ramp,0.,dw !填充数组
spins(1) = 0.1 !将数组第一个数字重新赋值为0.1

*do,iloop,1,nbstep !开始循环
   /solu
   antype,static !静力学分析
   rescontrol, linear    !为了随后的线性扰动分析，将结果写入文件
   coriolis,off,,,on !关闭陀螺效应
   omega,,,spins(iloop) !设置转速
   campbell,rstp !将结果保存用于随后的预应力结构的坎贝尔图分析
   solve
   fini
   /solu
   antype,static, restart,,,perturb !线性扰动静力学分析
   perturb, modal,,, INERKEEP    !线性扰动模态分析
   coriolis,on,,,on               !打开陀螺效应
   solve, elform                  !改善所有合适的单元矩阵
   modopt,qrdamp,20,,,on !提取模态的方式：QRdamp
   mxpand,20            !模态扩展
   omega,,,spins(iloop) !设置转速
   solve    !求解线性扰动
   fini
*enddo

!坎贝尔图
/post1
file,,rstp !读取后缀名为rstp的文件
/show,JPEG
plcamp
/show,CLOSE
prcamp
finish

来源：CSDN

作者：忧郁奔向冷的天

链接：https://blog.csdn.net/qq_37083038/article/details/104543790

标签

预应力