Oracle 常用函数及说明

参考：
https://blog.csdn.net/l690781365/article/details/82142888 (listagg函数的使用说明) https://zhidao.baidu.com/question/119144004.html (execute immediate)

listagg函数的使用说明

工作中经常遇到很多需求是这样的，根据条件汇总某些字段，比如我遇到的是，我们公司有三个投资平台，同一个客户拿手机号在三个平台都注册了，但注册过的用户名不一样，显示的时候需要根据手机号显示所有注册过的名称。(我用的是oracle数据库)

1、原始数据是这样的，如图：
在这里插入图片描述
2、要求显示成这样，如图：

我查了一下oracle函数，这个listagg函数就可以满足它，在网上看了看，都是介绍listagg这个函数的使用方法，看起来真费劲，于是在这里我简明扼要的说明一下

3、具体实现是这样的，也就不废话，看完例子都能懂：

select phone, listagg(log_name, ',') within group(order by phone) logName
  from int_phone
 where phone = '13350162230'
 group by phone

4、需要注意的事项如下：

必须得分组，也就是说group by是必须的。
listagg函数的第一个参数是需要显示的字段，也就是log_name；第二个参数是数值之间的分隔符；同时还需要进行排序和分组within group (order by name)

Oracle 查询库中所有表名、字段名、字段名说明，查询表的表名、中文表名

查询所有表名：

select t.table_name from user_tables t;

查询所有字段名：

select t.column_name from user_col_comments t;

查询指定表的所有字段名：

select t.column_name from user_col_comments t 
 where t.table_name = '指定表名';

查询指定表的所有字段名和字段说明：

select t.column_name, t.COMMENTS
  from user_col_comments t
 where t.table_name = '指定表名';

查询表的表名、中文表名

select t.table_name, f.comments
  from user_tables t
 inner join user_tab_comments f
    on t.table_name = f.table_name
 where t.table_name = '指定表名';

PL/SQL里 execute immediate 的用法

在ORACLE的PL/SQL里：EXECUTE IMMEDIATE 代替了以前Oracle8i中DBMS_SQL package包.

它解析并马上执行动态的SQL语句或非运行时创建的PL/SQL块.动态创建和执行SQL语句性能超前，EXECUTE IMMEDIATE的目标在于减小企业费用并获得较高的性能，较之以前它相当容易编码.尽管DBMS_SQL仍然可用，但是推荐使用EXECUTE IMMEDIATE,因为它获的收益在包之上。

使用技巧

EXECUTE IMMEDIATE将不会提交一个DML事务执行，应该显式提交。
如果通过EXECUTE IMMEDIATE处理DML命令，那么在完成以前需要显式提交或者作为EXECUTE IMMEDIATE自己的一部分。
如果通过EXECUTE IMMEDIATE处理DDL命令,它提交所有以前改变的数据。
不支持返回多行的查询,这种交互将用临时表来存储记录(参照例子如下)或者用REF cursors.
当执行SQL语句时，不要用分号，当执行PL/SQL块时，在其尾部用分号.
在Oracle手册中，未详细覆盖这些功能。
下面的例子展示了所有用到Execute immediate的可能方面.希望能给你带来方便.
对于Forms开发者,当在PL/SQL 8.0.6.3.版本中，Forms 6i不能使用此功能.

EXECUTE IMMEDIATE – 用法例子

1. 在PL/SQL运行DDL语句

begin
	execute immediate 'set role all';
end;

2. 给动态语句传值(USING 子句)

declare
	l_depnam varchar2(20) := 'testing';
	l_loc varchar2(10) := 'Dubai';
begin
	execute immediate 'insert into dept values (:1, :2, :3)'
	using 50, l_depnam, l_loc;
	commit;
end;

3. 从动态语句检索值(INTO子句)

declare
	l_cnt varchar2(20);
begin
	execute immediate 'select count(1) from emp'
	into l_cnt;
	dbms_output.put_line(l_cnt);
end;

4. 动态调用例程.例程中用到的绑定变量参数必须指定参数类型.
黓认为IN类型,其它类型必须显式指定

declare
	l_routin varchar2(100) := 'gen2161.get_rowcnt';
	l_tblnam varchar2(20) := 'emp';
	l_cnt number;
	l_status varchar2(200);
begin
	execute immediate 'begin ' || l_routin || '(:2, :3, :4); end;'
	using in l_tblnam, out l_cnt, in out l_status;
	if l_status != 'OK' then
	dbms_output.put_line('error');
	end if;
end;

5. 将返回值传递到PL/SQL记录类型;同样也可用%rowtype变量

declare
	type empdtlrec is record (empno number(4),
	ename varchar2(20),
	deptno number(2));
	empdtl empdtlrec;
begin
	execute immediate 'select empno, ename, deptno ' ||
	'from emp where empno = 7934'
	into empdtl;
end;

6. 传递并检索值.INTO子句用在USING子句前

declare
	l_dept pls_integer := 20;
	l_nam varchar2(20);
	l_loc varchar2(20);
begin
	execute immediate 'select dname, loc from dept where deptno = :1'
	into l_nam, l_loc
	using l_dept ;
end;

7. 多行查询选项.对此选项用insert语句填充临时表
用临时表进行进一步的处理,也可以用REF cursors纠正此缺憾.

declare
	l_sal pls_integer := 2000;
begin
	execute immediate 'insert into temp(empno, ename) ' ||
	' select empno, ename from emp ' ||
	' where sal > :1'
	using l_sal;
	commit;
end;

对于处理动态语句,EXECUTE IMMEDIATE 比以前可能用到的更容易并且更高效.
当意图执行动态语句时，适当地处理异常更加重要.应该关注于捕获所有可能的异常.

简单示例：

create or replace procedure proc_test(
--参数区域
)
is 
--变量区域
    --sql脚本
    v_sql varchar2(2000) :='';
    --记录学生数量
    v_num number;
begin
--执行区域

    -- execute immediate用法1：立刻执行sql语句
    v_sql := 'create or replace view myview as select id,name from student';
    execute immediate v_sql;
    
    --- execute immediate用法2：立刻执行sql语句，并赋值给某个变量
    v_sql := 'select count(1) from student';
    execute immediate v_sql into v_num;
    
    -- execute immediate用法3：带参数的sql
    v_sql:='select * from student t where t.name=:1 and t.age=:2'; 
    execute immediate v_sql using 'ZhangSan',23;
    
end proc_test;

持续更新…

来源：CSDN

作者：我家有只小熊二

链接：https://blog.csdn.net/hundan_520520/article/details/103895827

标签

Oracle

oracle函数

select

oracle数据库