Generate multiple lags through loops in SAS?

问题

I'm trying to generate 20 lags for a variable. To generate the first lag, I use the following statement:

data temp.data2;

    set temp.data1;
    by gvkey fyear; 
    lag1 =   ifn(gvkey=lag(gvkey) and fyear=lag(fyear)+1,lag(mv),.);
    lag2 =   ifn(gvkey=lag(gvkey) and fyear=lag(fyear)+1,lag(lag1),.); 
    etc.

run; 

Don't want to repeat 20 times. Is there a way to do this through a loop?

Thanks a lot!

回答1:

You would have to maintain your own array of mv values and assign the lag values from that. The array would be bubbled for each row processed and reset at the start of an fyear group.

Example:

data have; 
  do gvkey = 1 to 5;
    do fyear = 1 to 5;
      do day = 1 to ifn(fyear=3, 10, 30);
        mv = 366-day;
        output;
      end;
    end;
  end;
run;

data want;
  set have;
  by gvkey fyear;

  array mvs(20) _temporary_;
  array lags(20) lag1-lag20;

  if first.fyear then call missing(of mvs(*));

  * assign lags;
  do _n_ = 1 to dim(lags);
    lags(_n_) = mvs(_n_);
  end;

  * bubble mvs;
  do _n_ = dim(lags) to 2 by -1;
    mvs(_n_) = mvs(_n_-1);
  end;
  mvs(1) = mv;
run;

来源：https://stackoverflow.com/questions/57456363/generate-multiple-lags-through-loops-in-sas