Is it possible to grep Vim's quickfix?

问题

So let's say I use ag.vim to search 'disabled' through files. It returns me some results in quickfix window:

1 first_file.rb|1 col 1| disabled something something
2 second_file.rb|1 col 2| disabled another something

Is it possible to pick quickfix results as an input, grep through it and open results in new quickfix? So, if i would enter :quickfix_grep first_file, new quickfix would pop up with only 1 entry:

1 first_file.rb|1 col 1| disabled something something

回答1:

Update

A vim plugin has been written for this requirement: https://github.com/sk1418/QFGrep

Original Answer:

My understanding of your goal is:

Your grep result is somehow huge in your quickfix, you want to narrow your view of it. by entering a command with regex, filter the grep result. The filtered result should also be displayed in QuickFix window, so that you could open/jump to the file.

If the above is what you want, check out the following:

source this function and the command line:

function! GrepQuickFix(pat)
  let all = getqflist()
  for d in all
    if bufname(d['bufnr']) !~ a:pat && d['text'] !~ a:pat
        call remove(all, index(all,d))
    endif
  endfor
  call setqflist(all)
endfunction
command! -nargs=* GrepQF call GrepQuickFix(<q-args>)

then after your grep/ack/whatever show stuffs in your quickfix, you could type

:GrepQF <regex>

to do filtering in your quickfix.

Here I add an GIF animation. I am using Ack instead of grep, but it makes no difference. The given regex will match filename and the text showing in quickfix. I did filtering twice to show that.

hope it helps.

回答2:

My solution to this problem has always been to make the quickfix buffer modifiable by default:

:autocmd BufReadPost quickfix set modifiable

Doing this opens a whole range of possibilities for any appropriate edits like adding comments, removing unrelated entries manually or through filtering with the :global and :vglobal commands.

回答3:

Here's a shorter & neater version of @Kent's answer:

function! GrepQuickFix(pat)
  call setqflist(filter(getqflist(), "bufname(v:val['bufnr']) !~# a:pat"))
endfunction
command! -nargs=* GrepQF call GrepQuickFix(<q-args>)

It is the same code, just neater and shorter, I don't believe it deserves a separate plugin.

回答4:

New official vim plugin cfilter

Since 21.8.2018 (patch: 8.1.0311) the plugin cfilter is distributed with vim in $VIMRUNTIME. It is documented under :h cfilter-plugin.

Load plugin cfilter when needed or load it always in your vimrc

:packadd cfilter

Filter quickfix list with

:Cfilter DPUST

来源：https://stackoverflow.com/questions/15406138/is-it-possible-to-grep-vims-quickfix

标签

vim

grep