Using Forex Feed from XML in AS3?

问题

I would like to use this xml file for currency exchange rates in my AS3 flash file:

http://www.ecb.europa.eu/stats/eurofxref/eurofxref-daily.xml

So far, this is what I have:

var myXML:XML;
var myLoader:URLLoader = new URLLoader();

myLoader.load(new URLRequest("http://www.ecb.europa.eu/stats/eurofxref/eurofxref-daily.xml"));
 myLoader.addEventListener(Event.COMPLETE, processXML);

function processXML(e:Event):void {
myXML = new XML(e.target.data);
trace(myXML.*);
}

With this I get the whole xml document as an output.

How can I adress the various "cube currency" and "rate" values within as3?

Thanks for your help!

回答1:

    function processXML(e:Event):void {
        myXML = new XML(e.target.data);

        //set default xml to "", this allow to access to he Cube nodes by name
        var ns:Namespace =  myXML.namespace("");
        default xml namespace = ns;

        //list of Cube nodes
        var list:XMLList = myXML.Cube.Cube.*;
        var currency:String;
        var rate:Number;
        for each(var node:XML in list)
        {
            currency = String(node.@currency[0]);
            rate = node.@rate[0];
            trace(currency, rate);
        }
    }       

来源：https://stackoverflow.com/questions/14647356/using-forex-feed-from-xml-in-as3