How do I convert the time to military time?

问题

I am getting input from a file. The time maybe military or standard (AM/PM)

I need to convert the time to military.

Here are some examples of the time in the CSV file

2011-08-16, 2:28:00 PM, 15:28
2011-08-16, 1:21:00 PM, 13:28
2011-08-16, 2:13:00 PM, 16:28

回答1:

Firstly I'm not sure whether I understood the question correctly. Could be like this:

Option Explicit

Const SOURCE_PATH = "C:\source.csv"
Const DEST_PATH = "C:\destination.csv"
Dim oReg, oFso

Set oReg = New RegExp
oReg.IgnoreCase = True
oReg.Global = True
oReg.Pattern = "\b((1[0-2]|[1-9]):[0-5][0-9]:[0-5][0-9] [AP]M)\b"

Function cb_MilTime(a, b, c, d, e)
    cb_MilTime = FormatDateTime(CDate(b), 4)
    'cb_MilTime = Replace(cb_MilTime, ":", "") 'need seperator?
End Function

Set oFso = CreateObject("Scripting.FileSystemObject")

If oFso.FileExists(SOURCE_PATH) Then 
    oFso.OpenTextFile(DEST_PATH, 2, True).Write(oReg.Replace(_
    oFso.OpenTextFile(SOURCE_PATH).ReadAll(), GetRef("cb_MilTime")))
Else 
    Err.Raise 8, "Source path does not exists"
End If

WScript.Echo "File Saved to "& DEST_PATH

Set oFso = Nothing
Set oReg = Nothing

回答2:

Something like this should work:

Const militaryTimeFormat As String = "HH:mm"

' convert to a string in military time
Dim input As String = DateTime.Now.ToString(militaryTimeFormat)

' convert from a string in military time
Dim time As DateTime = DateTime.ParseExact(input, militaryTimeFormat, Nothing)

来源：https://stackoverflow.com/questions/7083986/how-do-i-convert-the-time-to-military-time

标签

scripting

vbscript