问题
I'm attempting to write an XSLT stylesheet that will handle author's names and create APA versions of the citation. The format for APA citation regarding author's name(s): Names are listed last name, then initials, if name(s) is the first element of the citation. Separate names with a comma, and an ampersand (&) before the last author. I followed Dimitre Novatchev's solution in this post:Using XSLT to select after EACH instance in a string/substring but I'm not getting the results I wanted.
Input:
<names>
<author>Lio-Po, Gilda D.</author>
<author>Primavera, Jurgenne H.</author>
<author>Cuvin-Aralar, Ma. Lourdes A.</author>
<author>Cruz, E.R.</author>
<author>Catacutan, M.R.</author>
<author>Agbayani, R.F.</author>
</names>
The desired output would be: Lio-Po, G. D., Primavera, J. H., Cuvin-Aralar, M. L. A., Cruz, E. R., Catacutan, M. R., & Agbayani, R. F.
For records with just 2 authors:
<names>
<author>Lio-Po, Gilda D.</author>
<author>Primavera, Jurgenne H.</author>
</names>
The desired output would be: Lio-Po, G. D., & Primavera, J. H.
Thanks in advance. Below is my code with some code taken from Dimitre's.
<xsl:strip-space elements="*"/>
<xsl:template match="/">
<xsl:for-each select="/names/author">
<xsl:choose>
<xsl:when test="count(following-sibling::text()) = 1">
<xsl:text>& </xsl:text>
<xsl:apply-templates/>
</xsl:when>
<xsl:when test="count(following-sibling::text()) != 0">
<xsl:apply-templates/>
<xsl:text>, </xsl:text>
</xsl:when>
</xsl:choose>
</xsl:for-each>
</xsl:template>
<xsl:template match="text()">
<xsl:value-of select="substring-before(., ',')"/>
<xsl:call-template name="replaceTokenDelims">
<xsl:with-param name="pStr" select="concat(normalize-space(substring-after(., ',')), ' ')"/>
<xsl:with-param name="pToken" select="' '"/>
<xsl:with-param name="pReplacement" select="', '"/>
</xsl:call-template>
</xsl:template>
<xsl:template name="replaceTokenDelims">
<xsl:param name="pStr"/>
<xsl:param name="pToken"/>
<xsl:param name="pReplacement"/>
<xsl:if test="$pStr">
<xsl:value-of select="$pReplacement"/>
<xsl:value-of select="substring(substring-before($pStr, $pToken),1,1)"/>
<xsl:call-template name="replaceTokenDelims">
<xsl:with-param name="pStr" select="substring-after($pStr, $pToken)"/>
<xsl:with-param name="pToken" select="$pToken"/>
<xsl:with-param name="pReplacement" select="$pReplacement"/>
</xsl:call-template>
</xsl:if>
</xsl:template>
Running the above code gives me the output: Lio-Po, G, D, Primavera, J, H, Cuvin-Aralar, M, L, A, Cruz, E, Catacutan, M, & Agbayani, R
回答1:
UPDATED
This one works, I even tested it myself:
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:str="http://exslt.org/strings">
<xsl:output method="text" />
<xsl:template match="/">
<xsl:for-each select="/names/author">
<xsl:if test="position() = last()">
<xsl:text>& </xsl:text>
</xsl:if>
<xsl:for-each select="str:tokenize(.,' ')">
<xsl:choose>
<xsl:when test="position() = 1">
<xsl:value-of select="."></xsl:value-of>
</xsl:when>
<xsl:when test="substring(.,2,1) = '.'">
<xsl:for-each select="str:tokenize(.,'.')">
<xsl:value-of select="concat(.,'.')"></xsl:value-of>
<xsl:if test="position() != last()">
<xsl:text> </xsl:text>
</xsl:if>
</xsl:for-each>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="concat(substring(.,1,1),'.')"></xsl:value-of>
</xsl:otherwise>
</xsl:choose>
<xsl:choose>
<xsl:when test="position() = last()">
<xsl:text>, </xsl:text>
</xsl:when>
<xsl:otherwise>
<xsl:text> </xsl:text>
</xsl:otherwise>
</xsl:choose>
</xsl:for-each>
</xsl:for-each>
</xsl:template>
And the output for your given XML would be:
Lio-Po, G. D., Primavera, J. H., Cuvin-Aralar, M. L. A., Cruz, E. R., Catacutan, M. R., & Agbayani, R. F.,
If you can live with the last extra comma ;)
APPEND: This is the full java code which I tested and looks ok.
import java.io.File;
import java.io.IOException;
import java.io.StringWriter;
import javax.xml.transform.TransformerException;
public class XLSTTester {
public static void main(String[] params){
try {
transform("d:\\workspace1\\test.xml","d:\\workspace1\\test.xsl");
} catch (TransformerException e) {
// TODO Auto-generated catch block
e.printStackTrace();
} catch (IOException e) {
// TODO Auto-generated catch block
e.printStackTrace();
}
}
private static void transform(String xmlFileFullPath, String xsltFileFullPath) throws TransformerException, IOException{
File xmlFile = new File(xmlFileFullPath);
File xsltFile = new File(xsltFileFullPath);
StringWriter sw = new StringWriter();
javax.xml.transform.Source xmlSource = new javax.xml.transform.stream.StreamSource(xmlFile);
javax.xml.transform.Source xsltSource = new javax.xml.transform.stream.StreamSource(xsltFile);
javax.xml.transform.Result transResult = new javax.xml.transform.stream.StreamResult(sw);
// create an instance of TransformerFactory
javax.xml.transform.TransformerFactory transFact = javax.xml.transform.TransformerFactory.newInstance( );
javax.xml.transform.Transformer trans = transFact.newTransformer(xsltSource);
trans.transform(xmlSource, transResult);
}
}
回答2:
I think I got it!
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:str="http://exslt.org/strings">
<xsl:output method="text"/>
<xsl:template match="/">
<xsl:for-each select="/names/author">
<xsl:variable name="firstname">
<xsl:value-of select="substring-after(., ', ')"/>
</xsl:variable>
<xsl:if test="position() = last() and position() != 1">
<xsl:text>& </xsl:text>
</xsl:if>
<xsl:choose>
<xsl:when test="substring($firstname,2,1) = '.'">
<xsl:value-of select="concat(str:tokenize(.,','), ', ')"/>
<xsl:for-each select="str:tokenize($firstname,'.')">
<xsl:value-of select="concat(.,'.')"/>
<xsl:if test="position() != last()">
<xsl:text> </xsl:text>
</xsl:if>
</xsl:for-each>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="concat(str:tokenize(.,','), ', ')"/>
<xsl:for-each select="str:tokenize($firstname,' ')">
<xsl:value-of select="concat(substring(.,1,1),'.')"/>
<xsl:if test="position() != last()">
<xsl:text> </xsl:text>
</xsl:if>
</xsl:for-each>
</xsl:otherwise>
</xsl:choose>
<xsl:if test="position() != last()">
<xsl:text>, </xsl:text>
</xsl:if>
</xsl:for-each>
</xsl:template>
If tested with the following input:
<names>
<author>Lio-Po, Gilda D.</author>
<author>Cuvin-Aralar, Ma. Lourdes A.</author>
<author>De la Cruz, Juan C.</author>
<author>Cruz, E.R.</author>
<author>Catacutan, M.R.</author>
<author>De los Santos, M.A.</author>
<author>Primavera, Jurgenne H.</author>
</names>
The desired result is produced:
Lio-Po, G. D., Cuvin-Aralar, M. L. A., De la Cruz, J. C., Cruz, E. R., Catacutan, M. R., De los Santos, M. A., & Primavera, J. H.
来源：https://stackoverflow.com/questions/13983833/using-xslt-to-parse-and-then-format-names