Check type of node in XSL template

问题

Is it possible to check the type of a node I matched with a template inside the same template? In case it is, how can I do it? For example I would like to do something like this:

<xsl:template match="@*|node()">
    <xsl:choose>
        <xsl:when test="current() is an attribute">
        <!-- ... -->
        </xsl:when>
        <xsl:when test="current() is an element">
        <!-- ... -->
        </xsl:when>
        <xsl:otherwise>
        <!-- ... -->
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

回答1:

Take a look at this answer here, as this should give you the information you need:

Difference between: child::node() and child::*

This gives the following xsl:choose to test all the nodes, including the document node.

<xsl:choose>
  <xsl:when test="count(.|/)=1">
    <xsl:text>Root</xsl:text>
  </xsl:when>
  <xsl:when test="self::*">
    <xsl:text>Element </xsl:text>
    <xsl:value-of select="name()"/>
  </xsl:when>
  <xsl:when test="self::text()">
    <xsl:text>Text</xsl:text>
  </xsl:when>
  <xsl:when test="self::comment()">
    <xsl:text>Comment</xsl:text>
  </xsl:when>
  <xsl:when test="self::processing-instruction()">
    <xsl:text>PI</xsl:text>
  </xsl:when>
  <xsl:when test="count(.|../@*)=count(../@*)">
    <xsl:text>Attribute</xsl:text>
  </xsl:when>
</xsl:choose>

回答2:

A more precise way to determine if the node $node is a root node:

not(count($node/ancestor::node()))

The expression in TimC's answer tests the type of the current node:

count(.|/)=1

but isn't applicable in the case when we want to determine the type of a node in a variable -- which may belong to another document -- not to the current document.

Also, a test for a namespace node:

count($node | $node/../namespace::*) = count($node/../namespace::*)

回答3:

I highly recommend you to use the expressions on sequence types introduced in XPath 2.0. For example:

. instance of document-node()
. instance of element()

来源：https://stackoverflow.com/questions/14118670/check-type-of-node-in-xsl-template

标签

xslt

xpath-1.0