bad request to Lxphnx.ArticleController.create, no matching action clause to process request

问题

I can do a GET request but I can't seem to get a POST request working.

These are my routes

article_path  GET     /api/articles      Lxphnx.ArticleController :index
article_path  GET     /api/articles/:id  Lxphnx.ArticleController :show
article_path  POST    /api/articles      Lxphnx.ArticleController :create
article_path  PATCH   /api/articles/:id  Lxphnx.ArticleController :update
              PUT     /api/articles/:id  Lxphnx.ArticleController :update
article_path  DELETE  /api/articles/:id  Lxphnx.ArticleController :delete

I haven't really touched anything except for using mix phoenix.gen.json. This project is an API only so I also used --no-brunch --no-html when creating the project.

Controller:

defmodule Lxphnx.ArticleController do
  use Lxphnx.Web, :controller

  alias Lxphnx.Article

  def index(conn, _params) do
    articles = Repo.all(Article)
    render(conn, "index.json", articles: articles)
  end

  def create(conn, %{"article" => article_params}) do
    changeset = Article.changeset(%Article{}, article_params)

    case Repo.insert(changeset) do
      {:ok, article} ->
        conn
        |> put_status(:created)
        |> put_resp_header("location", article_path(conn, :show, article))
        |> render("show.json", article: article)
      {:error, changeset} ->
        conn
        |> put_status(:unprocessable_entity)
        |> render(Lxphnx.ChangesetView, "error.json", changeset: changeset)
    end
  end

  def show(conn, %{"id" => id}) do
    article = Repo.get!(Article, id)
    render(conn, "show.json", article: article)
  end

  def update(conn, %{"id" => id, "article" => article_params}) do
    article = Repo.get!(Article, id)
    changeset = Article.changeset(article, article_params)

    case Repo.update(changeset) do
      {:ok, article} ->
        render(conn, "show.json", article: article)
      {:error, changeset} ->
        conn
        |> put_status(:unprocessable_entity)
        |> render(Lxphnx.ChangesetView, "error.json", changeset: changeset)
    end
  end

  def delete(conn, %{"id" => id}) do
    article = Repo.get!(Article, id)

    # Here we use delete! (with a bang) because we expect
    # it to always work (and if it does not, it will raise).
    Repo.delete!(article)

    send_resp(conn, :no_content, "")
  end
end

Router:

defmodule Lxphnx.Router do use Lxphnx.Web, :router

 pipeline :api do
   plug :accepts, ["json"]
 end

 scope "/api", Lxphnx do
   pipe_through :api
   resources "/articles", ArticleController, except: [:new, :edit]
 end
end

View:

defmodule Lxphnx.ArticleView do
  use Lxphnx.Web, :view

  def render("index.json", %{articles: articles}) do
    %{data: render_many(articles, Lxphnx.ArticleView, "article.json")}
  end

  def render("show.json", %{article: article}) do
    %{data: render_one(article, Lxphnx.ArticleView, "article.json")}
  end

  def render("article.json", %{article: article}) do
    %{id: article.id,
      title: article.title,
      body: article.body,
      type: article.type}
  end
end

Oh and I also tried this Phoenix.ActionClauseError at POST, no matching action clause to process request

I'm using cURL and I'm not forgetting to put that it's an application/json. Here is my curl request: curl -X POST -d '{"id":1, "title":"a title", "body":"a body", "type:1"}' -o log.txt localhost:4000/api/articles I get the same results if I use postman.

回答1:

In order for your function clause to match, you need to specify "article" in your curl request:

curl -X POST -d '{"article": {"id":1, "title":"a title", "body":"a body", "type:1"}}' -o log.txt localhost:4000/api/articles

If you don't want this top level key in your object, change:

def create(conn, %{"article" => article_params}) do
  changeset = Article.changeset(%Article{}, article_params)

to:

def create(conn, article_params) do
  changeset = Article.changeset(%Article{}, article_params)

来源：https://stackoverflow.com/questions/38535041/bad-request-to-lxphnx-articlecontroller-create-no-matching-action-clause-to-pro