vb.net deleting lots of dynamically created buttons

问题

I'm a new programmer to vb.net, so apologise for what is likely to be ignorance. I’m building a simple gui for a database interface, with many parent and child items within it. Upon a form I create buttons depending on how many items (parents/children). I've got the creation of the buttons thus:

For RowNumber As Integer = 0 To NoOfRows
        Dim Buttoni As New Button
        Buttoni.Location = New Point(LocationX, LocationY)
        Buttoni.Width = 100
        Buttoni.Height = 40
        Buttoni.Visible = True
        Buttoni.Text = DatasetA.Tables(0).Rows(RowNumber).Item("Name")
        ButtonName = "Button" + RowNumber.ToString

        If LocationX < FormWidth - (SpacePerButtonX * 2) Then
            LocationX = LocationX + SpacePerButtonX
        Else
            LocationX = 50
            LocationY = LocationY + SpacePerButtonY
        End If

        AddHandler Buttoni.Click, AddressOf DynamicButtonClick
        Me.Controls.Add(Buttoni)
        Buttoni.BringToFront()  'brings newest buttons to front!
    Next

But I’m struggling with a way to delete the buttons to make way for a new set to replace them... I can delete a single one upon its click, but I’d like to delete all of the buttons that have been created in this way before re-creating them.

I hope that makes sense and there is a fairly simple way to accomplish this..?

回答1:

I will add, in your creation loop, some value to the Tag property. This will help to differentiate the buttons created dinamically from the buttons created statically in your form.

Buttoni.Tag = 1

Then, to delete a button, loop in reverse order on the Me.Controls collection,
check if you get a button and if the Tag property IsNot Nothing

For x as Integer = Me.Controls.Count - 1 to 0 step -1)
    Dim b as Button = TryCast(Me.Controls(x), Button)
    If b IsNot Nothing AndAlso b.Tag IsNot Nothing then
        b.Dispose()       '' NOTE: disposing the button also removes it
    End If
Next

回答2:

It's hard to know exactly what you want to do. I guess you could just use the same technique in reverse, something like

        For i As Integer = Me.Controls.Count - 1 To 0 Step -1
            Dim ctrl = Me.Controls(i)

            If TypeOf (ctrl) Is Button Then
               ctrl.Dispose()           '' NOTE: disposing the control also removes it
            End If
        Next

回答3:

Create a button and delete it with double click! Easy Code :

Dim b As New Button
Private btn As Button ' this is a reference object
Private ptX, ptY As Integer
Private drag As Boolean
Private Sub nodebtn_MouseDown(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs)
    If e.Clicks = 2 Then
        b.Dispose()
    End If

    If e.Button = MouseButtons.Left Then
        drag = True
        btn = CType(sender, Button)
        ptX = e.X : ptY = e.Y
    End If
End Sub

Private Sub nodebtn_MouseMove(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs)
    If drag Then
        btn.Location = New Point(btn.Location.X + e.X - ptX, btn.Location.Y + e.Y - ptY)
        Me.Refresh()
    End If
End Sub
Private Sub nodebtn_MouseUp(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs)
    drag = False
End Sub

Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
    b.Location = New Point(10, 10)
    b.Size = New Size(110, 29)
    b.BringToFront()
    b.Text = "Button"
    AddHandler b.MouseDown, AddressOf nodebtn_MouseDown
    AddHandler b.MouseMove, AddressOf nodebtn_MouseMove
    AddHandler b.MouseUp, AddressOf nodebtn_MouseUp
    Me.Controls.Add(b)
End Sub

来源：https://stackoverflow.com/questions/10865183/vb-net-deleting-lots-of-dynamically-created-buttons

标签

vb.net

dynamic

runtime

controls