How to convert datetime in persian in sql server

I want to convert my datetime into persian datetime in sql server. My datetime is in MM/DD/YYYY format. Is there any function in sql server to do this as when i want hijri datetime i use this

 select CONVERT(VARCHAR(40), getdate(), 131) //Output is 14/08/1432 5:02:01:197PM

I'm using sql server 2008

Saman Gholami

I know it is too late for answering this question, but I've submitted the function that I'm using for a long time without any bug, all of other methods which I've ever seen have problem with intercalary years:

CREATE FUNCTION [CalculatePersianDate] ( @intDate DATETIME )
RETURNS NVARCHAR(max)
BEGIN

DECLARE @shYear AS INT ,@shMonth AS INT ,@shDay AS INT ,@intYY AS INT ,@intMM AS INT ,@intDD AS INT ,@Kabiseh1 AS INT ,@Kabiseh2 AS INT ,@d1 AS INT ,@m1 AS INT, @shMaah AS NVARCHAR(max),@shRooz AS NVARCHAR(max),@DayCnt AS INT
DECLARE @DayDate AS NVARCHAR(max)

SET @intYY = DATEPART(yyyy, @intDate)

IF @intYY < 1000 SET @intYY = @intYY + 2000

SET @intMM = MONTH(@intDate)
SET @intDD = DAY(@intDate)
SET @shYear = @intYY - 622
SET @DayCnt = 5

IF ( ( @intYY - 1992 ) % 4 = 0) SET @Kabiseh1 = 0 ELSE SET @Kabiseh1 = 1

IF ( ( @shYear - 1371 ) % 4 = 0) SET @Kabiseh2 = 0 ELSE SET @Kabiseh2 = 1

SET @m1 = 1
SET @d1 = 1
SET @shMonth = 10
SET @shDay = 11

IF ( ( @intYY - 1993 ) % 4 = 0 ) SET @shDay = 12


WHILE ( @m1 != @intMM ) OR ( @d1 != @intDD )
BEGIN

  SET @d1 = @d1 + 1
  SET @DayCnt = @DayCnt + 1

  IF 
  (@d1 = 32 AND (@m1 = 1 OR @m1 = 3 OR @m1 = 5 OR @m1 = 7 OR @m1 = 8 OR @m1 = 10 OR @m1 = 12))
  OR
  (@d1 = 31 AND (@m1 = 4 OR @m1 = 6 OR @m1 = 9 OR @m1 = 11))
  OR
  (@d1 = 30 AND @m1 = 2 AND @Kabiseh1 = 1)
  OR
  (@d1 = 29 AND @m1 = 2 AND @Kabiseh1 = 0)
  BEGIN
    SET @m1 = @m1 + 1
    SET @d1 = 1
  END

  IF @m1 > 12
  BEGIN
    SET @intYY = @intYY + 1
    SET @m1 = 1
  END

  IF @DayCnt > 7 SET @DayCnt = 1

 SET @shDay = @shDay + 1

  IF
  (@shDay = 32 AND @shMonth < 7)
  OR
  (@shDay = 31 AND @shMonth > 6 AND @shMonth < 12)
  OR
  (@shDay = 31 AND @shMonth = 12 AND @Kabiseh2 = 1)
  OR
  (@shDay = 30 AND @shMonth = 12 AND @Kabiseh2 = 0)
  BEGIN
    SET @shMonth = @shMonth + 1
    SET @shDay = 1
  END

  IF @shMonth > 12
  BEGIN
    SET @shYear = @shYear + 1
    SET @shMonth = 1
  END

END

IF @shMonth=1 SET @shMaah=N'فروردین'
IF @shMonth=2 SET @shMaah=N'اردیبهشت'
IF @shMonth=3 SET @shMaah=N'خرداد'
IF @shMonth=4 SET @shMaah=N'تیر'
IF @shMonth=5 SET @shMaah=N'مرداد'
IF @shMonth=6 SET @shMaah=N'شهریور'
IF @shMonth=7 SET @shMaah=N'مهر'
IF @shMonth=8 SET @shMaah=N'آبان'
IF @shMonth=9 SET @shMaah=N'آذر'
IF @shMonth=10 SET @shMaah=N'دی'
IF @shMonth=11 SET @shMaah=N'بهمن'
IF @shMonth=12 SET @shMaah=N'اسفند'

IF @DayCnt=1 SET @shRooz=N'شنبه'
IF @DayCnt=2 SET @shRooz=N'یکشنبه'
IF @DayCnt=3 SET @shRooz=N'دوشنبه'
IF @DayCnt=4 SET @shRooz=N'سه‌شنبه'
IF @DayCnt=5 SET @shRooz=N'چهارشنبه'
IF @DayCnt=6 SET @shRooz=N'پنجشنبه'
IF @DayCnt=7 SET @shRooz=N'جمعه'

--SET @DayDate = @shRooz + " " + LTRIM(STR(@shDay,2)) + " " + @shMaah + " " + STR(@shYear,4)
--پنجشنبه 17 اردیبهشت 1394

/*
SET @DayDate = LTRIM(STR(@shDay,2)) + " " + @shMaah + " " + STR(@shYear,4)
--17 اردیبهشت 1394

SET @DayDate = STR(@shYear,4) + "/"+LTRIM(STR(@shMonth,2)) + "/" + LTRIM(STR(@shDay,2))
--1394/2/17


--1394/02/17
*/
SET @DayDate = REPLACE(RIGHT(STR(@shYear, 4), 4), ' ', '0') + '/'+ REPLACE(STR(@shMonth, 2), ' ', '0') + '/' + REPLACE(( STR(@shDay,2) ), ' ', '0')
RETURN @DayDate
END

It is really easy to customize the result of the function. adopted from: this page

I know it is too late but maybe useful for others like me having this trouble.

You should write a SQL Function for this conversion like this: Converting Gregorian to Persian Date

and then use it like this:

SELECT dbo.[UDF_Gregorian_To_Persian]('2013-08-24')

Out of the box, no.

You'd have to write your own UDF, however there is one on CodePlex and another

convert Jalali to Georgian and Georgian to Jalali

try this link. there is some function that you can add in you SQL server and just call them when you need.

I believe the best available solution is to use SQLCLR-Jalali-Date-Utility. It has a straightforward installation guide and easy to use functions. Moreover, you can define the format of the converted date without any limitation. in fact, you can use the standard time formatting to define the shape of converted dates.

There are several examples provided inside the GitHub page.

select dbo.GregorianToJalali(GETDATE(),'yyyy/MM/dd hh:mm:ss tt') -- returns 1395/07/01 03:04:33 ب ظ

you can convert it to shamsi using this functions.

the first function. CREATE FUNCTION [dbo].[ToPersianDate](@dt [datetime]) RETURNS nvarchar WITH EXECUTE AS CALLER AS EXTERNAL NAME [PersianSQLFunctions].[UserDefinedFunctions].[ToPersianDate]

GO

second function. SET ANSI_NULLS OFF GO

SET QUOTED_IDENTIFIER OFF GO

CREATE FUNCTION [dbo].[ToPersianDate](@dt [datetime]) RETURNS nvarchar WITH EXECUTE AS CALLER AS EXTERNAL NAME [PersianSQLFunctions].[UserDefinedFunctions].[ToPersianDate]

GO

third function. CREATE FUNCTION [dbo].[fnToShamsiDate] ( @d DateTime ) RETURNS NVARCHAR(10) AS BEGIN -- Declare the return variable here DECLARE @RV NVARCHAR(10) IF (@d) IS NULL RETURN NULL; ELSE SELECT @RV = DBO.ToPersianDate(@D); -- Return the result of the function RETURN @RV

END

GO

and also you can find shamsi months from this function

create function [dbo].[fnGetShamsiMonth] ( @GregorianDate date ) returns nvarchar(2) as begin declare @ShamsiMonth nvarchar(2), @ShamsiDate nvarchar(10);

set @ShamsiDate = confsys.dbo.fnToShamsiDate(@GregorianDate);

set @ShamsiMonth = SUBSTRING(@ShamsiDate,6,2);

return @ShamsiMonth

end GO

examples

select confsys.dbo.fnToShamsiDate(getdate()) result is 1397/12/29

get shamsi months select confsys.dbo.fnGetShamsiMonth(GETDATE());

来源：https://stackoverflow.com/questions/6706692/how-to-convert-datetime-in-persian-in-sql-server

标签

sql-server-2008

datetime-format