Replace commas with pipes, but not the commas enclosed in double quotes

Question

I have a record set that looks like this

\"BOSW0001\",\"Mr\",\"Wayne\",\"Boswell\",\"Wayne,Jessica & Lyn\",\"31          


        

Answer 1

How about utilizing the context in which the comma appears (between double-quotes):

s/","/"|"/g

Answer 2

Just for the sake of TIMTOWTDI, here is an example using the core module Text::ParseWords.

#!/usr/bin/env perl

use strict;
use warnings;

use Text::ParseWords 'parse_line';

foreach my $line (<DATA>) {
  print join '|', parse_line(',', 1, $line);
}

__DATA__
"BOSW0001","Mr","Wayne","Boswell","Wayne,Jessica & Lyn","31 Baker St"
"ELLI0007","Mrs","Bronwyn","Elliott","Bronwyn, Paul & Arianne","98A Dandaraga Rd"
"KENN0001","Mr","Leigh","Kenning","Leigh & Beth,Cole","22 Lake St"

Answer 3

You don't do it with a regular expression; you do it with a proper CSV parser. Here's an (untested) example using Text::CSV_XS - the best in the biz.

use strict;
use warnings;

use Text::CSV_XS;

my $in_file = "whatever.csv";
my $out_file = "new.dat";

open my $fh, '<', $in_file or die "$in_file: $!";
open my $out_fh, '>', $out_file or die "$out_file: $!";

my $in_csv = Text::CSV_XS->new;
my $out_csv = Text::CSV_XS->new( { sep_char => '|', eol => "\n" } );

while( my $row = $in_csv->getline( $fh ) ) { 
    $out_csv->print( $out_fh, $row );
}