How to configure Grails 3.1.1 to use Hibernate 5

Question

How do I make Grails 3.1.1 user Hibernate 5?

The following actions report Hibernate version 4.3.11.Final: In Grails 3.1.1

1. grails create-app hello311

Answer 1

In build.gradle change the classpath dependency for the hibernate4 plugin at the top of the file in the buildscript{ dependencies {... section as follows:

classpath "org.grails.plugins:hibernate5:5.0.1"

The classpath section is there for the Gradle scrips like schemaExport, and that section does not support auto versioning.

Change the compile hibernate4 plugin dependency to the following:

compile "org.grails.plugins:hibernate5"

Add the following hibernate-core dependency:

compile "org.hibernate:hibernate-core:5.0.7.Final"

Change the hibernate-ehcache dependency to the 5.0.7.Final version.

compile "org.hibernate:hibernate-ehcache:5.0.7.Final"

Answer 2

In response to Ectoras comment on Burt's answer. Here is my full build.gradle file that works for me with Hibernate 5.

buildscript {
    ext {
        grailsVersion = project.grailsVersion
    }
    repositories {
        mavenLocal()
        maven { url "https://repo.grails.org/grails/core" }
    }
    dependencies {
        classpath "org.grails:grails-gradle-plugin:$grailsVersion"
        classpath "com.bertramlabs.plugins:asset-pipeline-gradle:2.5.0"
        classpath "org.grails.plugins:hibernate5:5.0.1"
        classpath "org.grails.plugins:views-gradle:1.0.1"
    }
}

version "0.1"
group "myGroup"

apply plugin: "spring-boot"
apply plugin: "war"
apply plugin: "asset-pipeline"
apply plugin: 'eclipse'
apply plugin: 'idea'
apply plugin: "org.grails.grails-web"
apply plugin: "org.grails.grails-gsp"
apply plugin: "org.grails.plugins.views-json"

ext {
    grailsVersion = project.grailsVersion
    gradleWrapperVersion = project.gradleWrapperVersion
}

assets {
    minifyJs = true
    minifyCss = true
}

repositories {
    mavenLocal()
    maven { url "https://repo.grails.org/grails/core" }
}

dependencyManagement {
    imports {
        mavenBom "org.grails:grails-bom:$grailsVersion"
    }
    applyMavenExclusions false
}

dependencies {
    compile "org.springframework.boot:spring-boot-starter-logging"
    compile "org.springframework.boot:spring-boot-starter-actuator"
    compile "org.springframework.boot:spring-boot-autoconfigure"
    compile "org.springframework.boot:spring-boot-starter-tomcat"
    compile "org.grails:grails-dependencies"
    compile "org.grails:grails-web-boot"
    compile "org.grails.plugins:cache"
    compile "org.grails.plugins:scaffolding"

    compile "org.grails.plugins:views-json:1.0.1"

    compile "org.grails.plugins:hibernate5"
    compile "org.hibernate:hibernate-core:5.0.7.Final"
    compile "org.hibernate:hibernate-ehcache:5.0.7.Final"

    console "org.grails:grails-console"
    profile "org.grails.profiles:web:3.1.1"
    runtime "org.grails.plugins:asset-pipeline"

    runtime files('grails-app/lib/ojdbc7.jar', 'grails-app/lib/xdb6.jar')
    compile files('grails/src/java')

    testCompile "org.grails:grails-plugin-testing"
    testCompile "org.grails.plugins:geb"

    // Note: It is recommended to update to a more robust driver (Chrome, Firefox etc.)
    testRuntime 'org.seleniumhq.selenium:selenium-htmlunit-driver:2.44.0'

    console "org.grails:grails-console"
}

task wrapper(type: Wrapper) {
    gradleVersion = gradleWrapperVersion
}