how to replace a string/word in a text file in groovy

Question

Hello I am using groovy 2.1.5 and I have to write a code which show the contens/files of a directory with a given path then it makes a backup of the file and replace a word/

Answer 1

Refer this answer where patterns are replaced. The same principle can be used to replace strings.

Sample

def copyAndReplaceText(source, dest, Closure replaceText){
    dest.write(replaceText(source.text))
}

def source = new File('source.txt') //Hello World
def dest = new File('dest.txt') //blank

copyAndReplaceText(source, dest) {
    it.replaceAll('World', 'World!!!!!')
}

assert 'Hello World' == source.text
assert 'Hello World!!!!!' == dest.text

Answer 2

other simple solution would be following closure:

def replace = { File source, String toSearch, String replacement ->
        source.write(source.text.replaceAll(toSearch, replacement))
    }

Answer 3

I use this code to replace port 8080 to ${port.http} directly in certain file:

    def file = new File('deploy/tomcat/conf/server.xml')
    def newConfig = file.text.replace('8080', '${port.http}')
    file.text = newConfig

The first string reads a line of the file into variable. The second string performs a replace. The third string writes a variable into file.

Answer 4

As an alternative to loading the whole file into memory, you could do each line in turn

new File( 'destination.txt' ).withWriter { w ->
  new File( 'source.txt' ).eachLine { line ->
    w << line.replaceAll( 'World', 'World!!!' ) + System.getProperty("line.separator")
  }
}

Of course this (and dmahapatro's answer) rely on the words you are replacing not spanning across lines

Answer 5

Answers that use "File" objects are good and quick, but usually cause following error that of course can be avoided but at the cost of loosen security:

Scripts not permitted to use new java.io.File java.lang.String. Administrators can decide whether to approve or reject this signature.

This solution avoids all problems presented above:

String filenew = readFile('dir/myfile.yml').replaceAll('xxx','YYY')
writeFile file:'dir/myfile2.yml', text: filenew

Answer 6

As with nearly everything Groovy, AntBuilder is the easiest route:

ant.replace(file: "myFile", token: "NEEDLE", value: "replacement")