How to use QMake's subdirs template?

前端 未结 2 2094
我在风中等你
我在风中等你 2020-11-28 02:29

I\'m starting to learn Qt. I\'m moving from the Visual Studio world and I am looking for a way to organize my project\'s structure using QMake. I\'ve found the \'subdirs\' t

相关标签:
2条回答
  • 2020-11-28 03:08

    You use subdirs if the logic and gui folders actually repesent some sort of target, eg. a library, that can be built independently of anything else. If that's the case then just use

    TEMPLATE = lib
    TARGET = logic
    CONFIG += dll
    

    in logic.pro.

    If they are not independent targets but are just folders that exist to organise the sources files then you can just use a .pri file in each instead and include them within the .pro using

    include(logic/logic.pri)
    include(gui/gui.pri)
    

    Just remember that the file paths in the .pri files are relative to the .pro file and not the .pri. BTW, the use of a .pri file is optional as you can still list the files in those folders directly in the .pro file. The .pri file just makes it that bit neater and helps keep the .pro file shorter.

    0 讨论(0)
  • 2020-11-28 03:20

    In addition to Troubadour's comment, I would note that the SUBDIRS target is only good for specifying subdirectories. Therefore, your extra line of

    SOURCES += main.cpp
    

    in your project.pro file is incorrect, and will likely fail to build your main.cpp file, at worst. At best, qmake will refuse to parse the file, since it has conflicting specifications in it.

    I've used the SUBDIRS template a few times, and it does well if you can build parts into more-or-less independent libraries, apparently like you have with the logic and the gui separate. Here is one way to do this:

    project_dir/
    -project.pro
    -common.pri
    -logic/
    ----logic.pro
    ----some logic files
    -gui/
    ----gui.pro
    ----gui files
    -build/
    ----build.pro
    ----main.cpp
    

    project.pro:

    TEMPLATE = subdirs
    SUBDIRS = logic \
              gui
    
    # build must be last:
    CONFIG += ordered
    SUBDIRS += build
    

    common.pri:

    #Includes common configuration for all subdirectory .pro files.
    INCLUDEPATH += . ..
    WARNINGS += -Wall
    
    TEMPLATE = lib
    
    # The following keeps the generated files at least somewhat separate 
    # from the source files.
    UI_DIR = uics
    MOC_DIR = mocs
    OBJECTS_DIR = objs
    

    logic/logic.pro:

    # Check if the config file exists
    ! include( ../common.pri ) {
        error( "Couldn't find the common.pri file!" )
    }
    
    HEADERS += logic.h
    SOURCES += logic.cpp
    
    # By default, TARGET is the same as the directory, so it will make 
    # liblogic.a (in linux).  Uncomment to override.
    # TARGET = target
    

    gui/gui.pro:

    ! include( ../common.pri ) {
        error( "Couldn't find the common.pri file!" )
    }
    
    FORMS += gui.ui
    HEADERS += gui.h
    SOURCES += gui.cpp
    
    # By default, TARGET is the same as the directory, so it will make 
    # libgui.a (in linux).  Uncomment to override.
    # TARGET = target
    

    build/build.pro:

    TEMPLATE = app
    
    SOURCES += main.cpp
    
    LIBS += -L../logic -L../gui -llogic -lgui
    
    # Will build the final executable in the main project directory.
    TARGET = ../project
    
    0 讨论(0)
提交回复
热议问题