How to define a function in ghci across multiple lines?

Question

I'm trying to define any simple function that spans multiple lines in ghci, take the following as an example:

let abs n | n >= 0 = n
          | otherwise = -n

So far I've tried pressing Enter after the first line:

Prelude> let abs n | n >= 0 = n
Prelude>           | otherwise = -n
<interactive>:1:0: parse error on input `|'

I've also attempted to use the :{ and :} commands but I don't get far:

Prelude> :{
unknown command ':{'
use :? for help.

I'm using GHC Interactive version 6.6 for Haskell 98 on Linux, what am I missing?

Answer 1

for guards (like your example), you can just put them all on one line and it works (guards do not care about spacing)

let abs n | n >= 0 = n | otherwise = -n

if you wanted to write your function with multiple definitions that pattern match on the arguments, like this:

fact 0 = 1
fact n = n * fact (n-1)

then you would use braces with semicolons separating the definitions

let { fact 0 = 1 ; fact n = n * fact (n-1) }

Answer 2

GHCi now has a multiline-input mode, enabled with :set +m. For example,

Prelude> :set +m
Prelude> let fac 0 = 1
Prelude|     fac n = n * fac (n-1)
Prelude|
Prelude> fac 10
3628800

Answer 3

Dan is correct, but :{ and :} must each appear on their own line:

> :{ 
> let foo a b = a +
>           b
> :}
> :t foo
foo :: (Num a) => a -> a -> a

This also interacts with the layout rule, so when using do-notation it might be easier to use braces and semi-colons explicitly. For example, this definition fails:

> :{
| let prRev = do
|   inp <- getLine
|   putStrLn $ reverse inp
| :}
<interactive>:1:18:
    The last statement in a 'do' construct must be an expression

But it works when braces and semi-colons are added:

> :{
| let prRev = do {
|   inp <- getLine;
|   putStrLn $ reverse inp;
| }
| :}
> :t prRev
prRev :: IO ()

This will only really matter when pasting definitions from a file, where indentation might change.

Answer 4

It looks like :{ and :} are a pretty new feature. You may need to upgrade GHC.

Edit: confirmed, see http://www.haskell.org/ghc/docs/6.8.2/html/users_guide/release-6-8-2.html

Answer 5

If you don't want to upgrade GHC just for :{ and :}, you'll need to write it all on one line:

> let abs' n | n >= 0 = n | otherwise = -n

I'm not aware of any single definition in Haskell that must be written on multiple lines. The above does indeed work in GHCi:

> :t abs'
abs' :: (Num a, Ord a) => a -> a

For other expressions, such as do blocks, you'll need to use the non-layout syntax with curly braces and semicolons (eugh).