Accesing a strict private field using the RTTI

Question

consider this simple code

{$APPTYPE CONSOLE}

uses
  Rtti,
  SysUtils;

type
  {$M+}
  TFoo = class
  strict private
    class var Field1 : Integer;
    field2 :  Integer;
  private
    field3 :  Integer;
    class var Field4 : Integer;
  end;


Var
    ctx : TRttiContext;
    f   : TRttiField;
begin
  try
    ctx:=TRttiContext.Create;

    for f in ctx.GetType(TFoo).GetFields do
     Writeln(f.Name);


    Writeln('Done');
    readln;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

When you run this, only the field3 is listed. it seems which the RTTI does not support fields which are strict private or class var, So the questions are Is possible access a strict private field of a delphi class using Rtti or another method? and I read the documentation of the RTTI.TRttiType.GetFields method but does mention these restrictions, Exist any paper or article which mentions such limitations?

Answer 1

I can't try it right now, but what you seem to need could be GetDeclaredFields instead of GetFields. This should give all (instance) fields of a class but not those of an ancestor class. If you need those too, you'll have to recursively go up the inheritance chain.

As I said, I can't try it right now, so you'll have to see for yourself if it gives you access to strict private fields as well.

Update

Note that in your declaration of TFoo, even you probably didn't intend it, both Field1 and Field2 are class variables!.

Just reformat your declaration, and you'll see what I mean:

  TFoo = class
  strict private
    class var
      Field1: Integer;
      Field2: Integer;
  private
    // etc...

Everything that comes after class var is a class variable, until the compiler encounters var, strict, private, protected, etc. Try this, and you'll also see Field2 being written:

  TFoo = class
  strict private
    class var 
      Field1: Integer;
    var 
      Field2: Integer;
    // etc...

Alternatively try:

  TFoo = class
  strict private
    Field2: Integer;
    class var 
      Field1: Integer;
    // etc...

This means that GetFields and GetDeclaredFields don't have any problems with strict private fields. They just don't return class variables. That makes sense, IMO. Class variables are not members of the object being investigated.

Answer 2

Access to strict private members of a class is possible with Class Helpers.

See access-a-strict-protected-property-of-a-delphi-class for a working example.

Related is also how-can-access-the-value-of-a-class-var-using-the-address-of-the-class-and-a-offset-to-the-variable, where class helpers is used to access a strict private class var.

Answer 3

By definition, strict private is only visible in the scope of the class itself. They should still be accessible with Hallvard's hack #5, though (except for class fields, I think).