目录
1. strcpy函数
将一个字符串复制到另一个字符型指针或字符数组，覆盖原来的字符串。
C语言中的调用方法：strcpy(目标字符串,源字符串)
在批处理中的实现方法：
set 目标字符串=%源字符串%
示例：
@echo off
::关闭屏幕回显（可选）
set str1=This is old string
::设置str1中存储的字符串，注意没有双引号，这点与C语言等不同！
set str2=This is new string
::设置str2中存储的字符串
echo 执行字符串拷贝以前：
echo str1=%str1%
echo str2=%str2%
::先输出一次原有的字符串
set str1=%str2%
::字符串拷贝
echo 执行字符串拷贝以后：
echo str1=%str1%
echo str2=%str2%
::输出执行完字符串拷贝后的字符串
echo 输出完毕，按任意键退出&&pause>nul&&exit
::输出信息，当用户按任意键时，结束该批处理。
2. strcat函数
将一个字符串连接到另一个字符型指针或字符数组的末尾。
C语言中的调用方法：strcat(目标字符串,源字符串)
在批处理中的实现方法：
set 目标字符串=%目标字符串%%源字符串%
示例：
@echo off
set str1=This is string1
set str2=This is string2
::设置str1和str2中存储的字符串
echo 连接字符串以前：
echo str1=%str1%
echo str2=%str2%
::先输出一次原有的字符串
set str1=%str1%%str2%
::字符串连接
echo 连接字符串以后：
echo str1=%str1%
echo str2=%str2%
::输出执行完字符串连接后的两个字符串
echo 输出完毕，按任意键退出&&pause>nul&&exit
3. strlen函数
取得字符串的长度。
C语言中的调用方法：strlen(字符串)
在批处理中的实现方法是利用goto和标签，形成循环结构，不断将字符串截短1字符，并用变量记录截短的次数，直到字符串变成空串。
示例：
@echo off
set str1=This is a test string
set str2=Hello World
::设置两个字符串
set str=%str1%
::将str1复制到str
:next1
::标签，用于goto跳转
::注意与注释语句的区别，注释用两个冒号开头，标签则为一个冒号
if not "%str%"=="" (
::判断str是不是空串，如果不是则执行下边的语句
set /a num+=1
::算术运算，使num的值自增1，相当于num++或者++num语句
set "str=%str:~1%"
::截取字符串，赋给自身
goto next1
::跳转到next1标签
::这里利用goto和标签，构成循环结构
)
::当以上循环结构执行完毕时，会执行下边的语句
echo str1=%str1%
echo str1的长度为：%num%
::输出结果
set num=0
::将记和用的环境变量num置0，以便开始下一次运算。
set str=%str2%
::将str2复制到str
:next2
::定义一个新的标签
::注意不能与已有的标签同名，否则会出错！
if not "%str%"=="" (
set /a num+=1
set "str=%str:~1%"
goto next2
)
::和上一个循环相似，不再介绍
echo str2=%str2%
echo str2的长度为：%num%
::输出结果
echo 输出完毕，按任意键退出&&pause>nul&&exit
4. strchr函数
在一个字符串中查找一个字符的首次出现位置，找到时返回所在位置，找不到时返回0值。
批处理中的思路：不断截短字符串，并取截短后字符串中的首字符，和要求的字符比较，如果相同就利用goto语句跳出循环，输出结果，如果没有相同的字符，执行到最后就输出0值。
示例：
@echo off
Setlocal ENABLEDELAYEDEXPANSION
::启用命令扩展，参加setlocal /?命令
set str1=This is a test string
set ch1=t
::注意，这里是区分大小写的！
set str=%str1%
::复制字符串，用来截短，而不影响源字符串
:next
if not "%str%"=="" (
set /a num+=1
if "!str:~0,1!"=="%ch1%" goto last
::比较首字符是否为要求的字符，如果是则跳出循环
set "str=%str:~1%"
goto next
)
set /a num=0
::没有找到字符时，将num置零
:last
echo 字符'%ch1%'在字符串"%str1%"中的首次出现位置为%num%
echo 输出完毕，按任意键退出&&pause>nul&&exit
5. strstr函数
在字符串1中查找是否存在字符串2，如果存在返回true，如果不存在返回false。
批处理中的思路：将字符串1中字符串2替换为空，再将新字符串1与老字符串1进行比较，如果相同，则说明不存在，如果不同，则说明存在。
示例：
@echo off
Set var=abccadadfasdga
If “%var:abc=%” == “%var%” (echo false) else (echo true)
pause
来源：https://blog.csdn.net/edestiny1/article/details/101079428