DataGridView to CSV File

Question

I have a VB 2010 Express Project, that has a DataGridView in it, that I am trying to write to a CSV file.

I have the write all working. But its slow. Slow = maybe 30 seconds for 6000 rows over 8 columns.

Here is my code:

    Private Sub btnExportData_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnExportData.Click
    Dim StrExport As String = ""
    For Each C As DataGridViewColumn In DataGridView1.Columns
        StrExport &= """" & C.HeaderText & ""","
    Next
    StrExport = StrExport.Substring(0, StrExport.Length - 1)
    StrExport &= Environment.NewLine

    For Each R As DataGridViewRow In DataGridView1.Rows
        For Each C As DataGridViewCell In R.Cells
            If Not C.Value Is Nothing Then
                StrExport &= """" & C.Value.ToString & ""","
            Else
                StrExport &= """" & "" & ""","
            End If
        Next
        StrExport = StrExport.Substring(0, StrExport.Length - 1)
        StrExport &= Environment.NewLine
    Next

    Dim tw As IO.TextWriter = New IO.StreamWriter("C:\Test1.CSV")
    tw.Write(StrExport)
    tw.Close()
End Sub

Does anyone know what I can do to speed it up?

thanks

Answer 1

Don't you just love it when you spend hours searching, then post a question, and a few minutes later find the answer yourself?

This did the trick for me:

Dim headers = (From header As DataGridViewColumn In DataGridView1.Columns.Cast(Of DataGridViewColumn)() _
              Select header.HeaderText).ToArray
Dim rows = From row As DataGridViewRow In DataGridView1.Rows.Cast(Of DataGridViewRow)() _
           Where Not row.IsNewRow _
           Select Array.ConvertAll(row.Cells.Cast(Of DataGridViewCell).ToArray, Function(c) If(c.Value IsNot Nothing, c.Value.ToString, ""))
Using sw As New IO.StreamWriter("csv.txt")
    sw.WriteLine(String.Join(",", headers))
    For Each r In rows
        sw.WriteLine(String.Join(",", r))
    Next
End Using
Process.Start("csv.txt")

Answer 2

Private Sub cmdExport_Click(sender As Object, e As EventArgs) Handles cmdExport.Click
'This way increases performance without casting
        Dim filePath As String = "OverrideViewer.csv"
        Dim delimeter As String = ","
        Dim sb As New StringBuilder
        For i As Integer = 0 To dgDataView.Rows.Count - 1
            Dim array As String() = New String(dgDataView.Columns.Count - 1) {}
            If i.Equals(0) Then
                For j As Integer = 0 To dgDataView.Columns.Count - 1
                    array(j) = dgDataView.Columns(j).HeaderText
                Next
                sb.AppendLine(String.Join(delimeter, array))
            End If
            For j As Integer = 0 To dgDataView.Columns.Count - 1
                If Not dgDataView.Rows(i).IsNewRow Then
                    array(j) = dgDataView(j, i).Value.ToString
                End If
            Next
            If Not dgDataView.Rows(i).IsNewRow Then
                sb.AppendLine(String.Join(delimeter, array))
            End If
        Next
        File.WriteAllText(filePath, sb.ToString)
'Opens the file immediately after writing
        Process.Start(filePath)
End Sub