Hey I have created a Groovy script that will extract the version numbers of some folder. I would then like to compare the version numbers and select the highest.
I got my script to run through the dir folder and I then get the versions in this format: 02.2.02.01
So I could get something like this:
- 02.2.02.01
- 02.2.02.02
- 02.2.03.01
I don't have them as a list but like this:
baseDir.listFiles().each { file ->
def string = file.getName().substring(5, 15)
// do stuff
}
Also I have tested that Groovy could compare them with the > operator and it can! But now I need to select the one with the highest version
This appears to work
String mostRecentVersion(List versions) {
def sorted = versions.sort(false) { a, b ->
List verA = a.tokenize('.')
List verB = b.tokenize('.')
def commonIndices = Math.min(verA.size(), verB.size())
for (int i = 0; i < commonIndices; ++i) {
def numA = verA[i].toInteger()
def numB = verB[i].toInteger()
println "comparing $numA and $numB"
if (numA != numB) {
return numA <=> numB
}
}
// If we got this far then all the common indices are identical, so whichever version is longer must be more recent
verA.size() <=> verB.size()
}
println "sorted versions: $sorted"
sorted[-1]
}
Here is an inadequate set of tests. You should add some more.
assert mostRecentVersion(['02.2.02.01', '02.2.02.02', '02.2.03.01']) == '02.2.03.01'
assert mostRecentVersion(['4', '2']) == '4'
assert mostRecentVersion(['4.1', '4']) == '4.1'
assert mostRecentVersion(['4.1', '5']) == '5'
Run this code and the tests in the Groovy console to verify that it works
If we're going for the shortest answer, this must come close ;-)
String mostRecentVersion( List versions ) {
versions.sort( false ) { a, b ->
[a,b]*.tokenize('.')*.collect { it as int }.with { u, v ->
[u,v].transpose().findResult{ x,y-> x<=>y ?: null } ?: u.size() <=> v.size()
}
}[-1]
}
If anyone is using Grails (e.g. Grails 2.2.3), I think VersionComparator already provides exactly what we need.
If you are not using Grails, you can always Google the source code of this class.
Example of working tests:
import org.codehaus.groovy.grails.plugins.VersionComparator
assert ['1.13.4', '1.4.5'].sort( new VersionComparator() ) == ['1.4.5', '1.13.4']
assert ['3.1.20', '3', '3.0.1', '3.1'].sort( new VersionComparator() ) == ['3', '3.0.1', '3.1', '3.1.20']
assert ['02.2.02.02', '02.2.03.01', '02.2.02.01'].sort( new VersionComparator() ) == ['02.2.02.01', '02.2.02.02', '02.2.03.01']
assert ['4', '2'].sort( new VersionComparator() ) == ['2', '4']
assert ['4.1', '4'].sort( new VersionComparator() ) == ['4', '4.1']
assert ['4.1', '5'].sort( new VersionComparator() ) == ['4.1', '5']
assert new VersionComparator().compare( '1.13.4', '1.4.5' ) > 0
assert new VersionComparator().compare( '1.4.5', '1.13.4' ) < 0
Hope this helps.
Mine is the shortest! lol )
versions = versions.sort {a, b ->
def a1 = a.tokenize('.')*.toInteger(), b1 = b.tokenize('.')*.toInteger()
for (i in 0..<[a1.size(), b1.size()].min())
if (a1[i] != b1[i]) return a1[i] <=> b1[i]
0
}
String maxVersion(versions) {
versions.max { a, b ->
List verA = a.tokenize('.')
List verB = b.tokenize('.')
def commonIndices = Math.min(verA.size(), verB.size())
for (int i = 0; i < commonIndices; ++i) {
def numA = verA[i].toInteger()
def numB = verB[i].toInteger()
if (numA != numB) {
return numA <=> numB
}
}
verA.size() <=> verB.size()
}
}
The code I am using with Jenkins ExtendedChoiceParameter (tolerant to non-integer fragments in the version string)
def vers = ['none']
new File(this.getBinding().getVariable('dir')).eachDir() { dir -> dirs.add(dir.getName()) }
vers.sort{x, y ->
def xa = x.tokenize('._-'); def ya = y.tokenize('._-')
def sz = Math.min(xa.size(), ya.size())
for (int i = 0; i < sz; ++i) {
def xs = xa[i]; def ys = ya[i];
if (xs.isInteger() && ys.isInteger()) {
def xn = xs.toInteger()
def yn = ys.toInteger()
if (xn != yn) { return xn <=> yn }
} else if (xs != ys) {
return xs <=> ys
}
}
return xa.size() <=> ya.size()
}.reverse().join(',')
Here's a slightly modified version of Nikita's contribution:
List versions = [ '02.2.02.01', '02.2.02.02', '02.2.03.01']
String mostRecentVersion = versions.sort {a, b ->
def a1 = a.tokenize('.')*.toInteger(), b1 = b.tokenize('.')*.toInteger()
for (i in 0..<[a1.size(), b1.size()].min()){
if (a1[i] != b1[i]) {
return a1[i] <=> b1[i]
}
}
}[-1]
assert mostRecentVersion == '02.2.03.01'
Here is a modification of Tim's answer which takes two version strings and returns a boolean (true if the first is newer than the second)
String v1 = '02.2.01.02'
String v2 = '02.2.06.02'
boolean isMoreRecent( String a, String b ) {
[a,b]*.tokenize('.')*.collect { it as int }.with { u, v ->
Integer result = [u,v].transpose().findResult{ x,y -> x <=> y ?: null } ?: u.size() <=> v.size()
return (result == 1)
}
}
assert !isMoreRecent(v1,v2)
assert isMoreRecent(v2,v1)
I use gradle 4.1 in Android Studio 3.0 Beta 7. There is VersionNumber.java (under C:\Users\ssfang.gradle\wrapper\dists\gradle-4.1-all\bzyivzo6n839fup2jbap0tjew\gradle-4.1\src\core\org\gradle\util)
For example:
apply plugin: 'com.android.application'
try{ // undocumented
println "${android.plugin.getSdkFolder().getAbsolutePath()}"
// Since 1.3.1 or 1.5.0? android studio version or android gradle plugin?
println "${android.getSdkDirectory().getAbsolutePath()}"
}catch (ignored){
}
// As of android gradle plugin v2.1.2
println android.sdkDirectory.path
println android.ndkDirectory.path
def buildToolsVer = new File(android.sdkDirectory.path, 'build-tools').listFiles().collect{ VersionNumber.parse(it.getName()) }.sort()
println buildToolsVer
printf('%s, %s\n', buildToolsVer.head(), buildToolsVer.last().toString())
def String mostRecentVersion(List<String> versions) {
// TreeMap<VersionNumber, String> verNum2StrMap = versions.collectEntries(new TreeMap(), { [VersionNumber.parse(it), it] })
// TreeMap<VersionNumber, String> verNum2StrMap = versions.inject(new TreeMap()) { memo, entry ->
// memo[VersionNumber.parse(entry)] = entry
// memo
// }
TreeMap<VersionNumber, String> verNum2StrMap = versions.inject(new TreeMap()) { map, verStr ->
map << [(VersionNumber.parse(verStr)): verStr]
}
// println verNum2StrMap.lastEntry().value
verNum2StrMap.lastEntry().value
}
assert mostRecentVersion(['02.2.02.01', '02.2.02.02', '02.2.03.01']) == '02.2.03.01'
assert mostRecentVersion(['4', '2']) == '4'
assert mostRecentVersion(['4.1', '4']) == '4.1'
assert mostRecentVersion(['4.1', '5']) == '5'
android {
compileSdkVersion 25
buildToolsVersion "26.0.2"
defaultConfig {
applicationId "ss.xsigner"
minSdkVersion 14
targetSdkVersion 22
versionCode 1
versionName "1.0"
testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
setProperty("archivesBaseName", "xsigner")
}
}
--
Here my solution:
def availVersion = "1.5.0.2"
def ownVersion = "2.6.0.1"
def availTokens = availVersion.split('\\.')
def ownTokens = ownVersion.split('\\.')
def availSize = availTokens.size()
def ownSize = ownTokens.size()
def maxSize = Math.max(availSize, ownSize)
for (int i = 1; i <= maxSize; i++) {
def availItem = ((i <= availSize) ? availTokens[i - 1] : 0)
def ownItem = ((i <= ownSize) ? ownTokens[i - 1] : 0)
print "Avail: ${availItem} -> Own: ${ownItem}\n"
if ((ownItem > availItem) || ( (i == maxSize) && (ownItem >= availItem) )) {
print "Upgrade NOT needed.\n"
return
}
}
print "Upgrade needed!\n"
As long as versions are contained in strings, why not use String comparison properties ? (or I missed something ?)
example :
v1 = "1.2.6.5"
v2 = "1.3.4"
assert (v1 != v2)
assert (v1 < v2)
assert (v1 <= v2)
assert !(v1 > v2)
def availVersion = "1.5.0.2"
def ownVersion = "2.6.0.1"
assert (availVersion != ownVersion)
assert (availVersion < ownVersion)
assert (availVersion <= ownVersion)
assert !(availVersion > ownVersion)
I did the following to determine latest version and it works pretty well :
ma_list = [v1, v2, "2.6.1.0.0", availVersion, ownVersion]
latest = ""
ma_list.each{
//println it
if (it > latest)
latest = it
}
assert (latest == "2.6.1.0.0")
println "latest = $latest"
来源：https://stackoverflow.com/questions/7723322/compare-version-strings-in-groovy