问题
I have a batch file that opens a URL to download a csv file, then I need to move and then rename that csv form downloads folder to other one.
What I have is:
@echo off
SET CCDIR=C:\Users\(username)\Desktop
SET LOADDIR=C:\Users\(username)\Downloads
ECHO ***************************************************************************
ECHO Downloading the file
ECHO ***************************************************************************
start chrome (URL string)
:NEXT
ECHO ***************************************************************************
ECHO Move CSV file from Downloads folder to Desktop
ECHO ***************************************************************************
move %LOADDIR%\*(file string)* %CCDIR%
ren %CCDIR%\*(file string)* (new file name)
I want to execute it all in the same bat, but just the start chrome is working, the bat is ignoring the move and ren.
How can I do that?
回答1:
Based on my comment, you can give a try for this example to download a file with Certuil command
@echo off
Title Downloading a file using Certutil Command
Mode 70,5 & color 0A
SET CCDIR=%userprofile%\Desktop
SET LOADDIR=%userprofile%\Downloads
set "url=https://download.sysinternals.com/files/PSTools.zip"
echo(
ECHO ******************************************************************
ECHO Please wait a while ... Downloading the file ...
ECHO ******************************************************************
Call :download %url% %LOADDIR%
Rem Moving the downloaded file from the folder Downloads to Desktop
move /Y "%file%" "%CCDIR%\">nul
Rem Open the desktop folder with explorer
Explorer "%CCDIR%\"
goto :eof
::--------------------------------------------
:Download <Url> <File>
Set url="%~1"
Set file=%2\%~nx1
certutil.exe -urlcache -split -f %url% %file%>nul
Rem Deleting cache
certutil -urlcache "%~1" delete>nul
Rem Check referenced urlcache is deleted
certutil.exe -v -urlcache -split "%~1">nul
exit /b
::--------------------------------------------
来源：https://stackoverflow.com/questions/52456253/downloading-file-from-url-using-start-chrome