Why am I getting “called too early to check prototype” warnings in my Perl code?

问题

I have a Perl file like this:

use strict;
f1();

sub f3()
{ f2(); }

sub f1()
{}
sub f2()
{}

In short, f1 is called before it is defined. So, Perl throws a warning: "f1 called too early to check prototype". But same is the case with f2, the only diff being that it is called from inside another subroutine. It doesn't throw a warning for f2. Why?

What is the best way to resolve this issue?

declare the subroutine before it is called
call the sub like this: &f1();

回答1:

You can completely avoid this issue by not using prototypes in the first place:

use strict;

f1();

sub f3 { f2() }

sub f1 {}
sub f2 {}

Don't use prototypes unless you know why you are using them:

This is all very powerful, of course, and should be used only in moderation to make the world a better place.

回答2:

Simply remove the () from your subroutine definitions. When you define with (), Perl thinks these are prototypes and you have to define your prototype before you use it.

Try this......

use strict;
f1();

sub f3
{ f2(); }

sub f1
{}
sub f2
{}

回答3:

The lack of a warning on the call to f2() from f3() appears to be a bug.

use strict;
use warnings;

f1();

sub f1 {
    my @a = qw(a b c);
    f2(@a);
}

sub f2(\@) { print $_[0] }

This prints "a". If you either predeclare f2() or swap the order of the subroutine definitions, it prints "ARRAY(0x182c054)".

As for resolving the situation, it depends. My preferences (in order) would be:

Remove the prototypes from the subroutine definitions. Perl's prototypes don't do what most people expect them to. They're really only useful for declaring subs that act like builtins. Unless you're trying to extend Perl's syntax, don't use them.
Predeclare the subroutines before using them. This lets Perl know about the prototype before the encountering any calls.
Reorder the code so that the subroutine definitions appear before any calls.
Call the subroutines using the &foo() notation to bypass prototype checking.

回答4:

If you are going to call it with the parenthesis, why are you even using prototypes?

sub f1(){ ... }

f1();

The only time I would use the empty prototype is for a subroutine that I want to work like a constant.

sub PI(){ 3.14159 }

print 'I like ', PI, ", don't you?\n";

I would actually recommend against using Perl 5 prototypes, unless you want your subroutine to behave differently than it would otherwise.

sub rad2deg($){ ... }

say '6.2831 radians is equal to ', rad2deg 6.2831, " degrees, of course.\n";

In this example, you would have to use parenthesis, if it didn't have a prototype. Otherwise it would have gotten an extra argument, and the last string would never get printed.

回答5:

When you define a function in Perl you should not use parentheses. When you do so you get this error. This is wrong:

sub DoSomthing(){
   #do what ever...
}

This is the way to go:

sub DoSomthing{
   #do what ever...
}

no parentheses.

For more detailed explenation see Gabor Szabo's Perl Maven page on Subroutines and functions in Perl. https://perlmaven.com/subroutines-and-functions-in-perl

来源：https://stackoverflow.com/questions/1719990/why-am-i-getting-called-too-early-to-check-prototype-warnings-in-my-perl-code

标签

perl

subroutine