Display the non selected parameter in SSRS

问题

In case of Multi-valued parameters,we usually use join function to display the selected values into a Text-box.But what if I wanted Show only the non selected parameters?IE If there are 10 values in the drop down list of a parameter and I selected the first 5 and wanted to display only the remaining 5 parameter instead of the first 5.What do i do?

回答1:

I have created a multivalue parameter with the name Param which has had its labels and values set like so:

Label    Value
======   =====
Label1     1
Label2     2
Label3     3
Label4     4
Label5     5

I then created the following code in the Report Properties --> Code menu:

    'Global array objects to hold the total and selected values
Private Dim parameterList() AS string
Private Dim selectedParameters() AS string


    'populates the list of all parameters using split and returns the input string
Public Function SetParameterList(nextParameter as String) AS String

    parameterList = Split(nextParameter ,",")

    Return nextParameter

End Function


    'populates the list of selected parameters using split and returns the input string
Public Function SetSelectedParameters(delimitedParameters as String) AS String

    selectedParameters = Split(delimitedParameters,",")

    Return delimitedParameters 

End Function


    'Returns the not selected parameters
Public Function GetNotSelectedParameters() AS String

    Dim notSelected As String
    Dim i as Integer
    Dim x as Integer

            'Loop through each value in the all parameters array...
    For i = 0 to parameterList.GetUpperBound(0)

                    '...for each one of those values check it against the selected parameters
        For x = 0 to selectedParameters.GetUpperBound(0)

                            'Where there is a match, set the all parameters value to a string unlikely to be a genuine parameter value
            IF parameterList(i) = selectedParameters(x) Then

                parameterList(i) = "!*!"

            End IF
        Next

    Next

            'Join the all parameters array back into a string 
    notSelected = Join(parameterList, ", ") 


            'Remove the !*! values added earlier from the middle and the end of the string
    notSelected = Replace(notSelected, "!*!, ", "")
    notSelected = Replace(notSelected, ", !*!", "")


    Return notSelected

End Function

To use this code I created 3 textboxes with the following expressions:

 =Code.SetParameterList(Join(LookUpSet(1,1,Fields!ParamLabel.Value,"DataSet1"),","))

 =Code.SetSelectedParameters(Join(Parameters!Param.Label, ","))

 =Code.GetNotSelectedParameters()

Note: to hide the output of any of these textboxes, you could set the function return value to be "".

I imagine my code could be improved upon significantly, but this gets the job done and should at least point you in the right direction.

回答2:

First create a multivalued parameter ("param1"), with available values ranging from 1 to 10.

Then create a query (query1), which returns the parameters from 1 to 10 filtering out the selected values from "param1" -> where query1.col NOT IN (@param1)

Then create another multivalued parameter("param2"), set a default value (get values from a query) point to "query1" to fill in the unselected values

use a text box with the following code "=Join(Parameters!param1.Value,",")"

To make query1 you can use unions.

You will get back the values not selected,

来源：https://stackoverflow.com/questions/21237135/display-the-non-selected-parameter-in-ssrs