MS Access 2013 calling insert queries from VBA with strange errors

问题

I have a saved insert query to add a record to a table. The parameters for the query come from an unbound form. 2 of the fields for the table are of the yes/no data type. The form control for these fields is a checkbox.

Here is the saved query "qryInsertLog"

PARAMETERS UserPar Text ( 255 ), ApprovedByPar Text ( 255 ), CCedByPar Text ( 255 ), 
           UnitIdPar Short, NotePar LongText, Z3Par Bit, Z5Par Bit, FollowupNotesPar LongText;

INSERT INTO tblLogBook ( [User], ApprovedBy, CCedBy, UnitID, Notes, Z3, Z5, FollowupNotes )

SELECT [UserPAR] AS Expr1, [ApprovedByPar] AS Expr2, [CCedByPar] AS Expr3, 
       [UnitIDPar] AS Expr4, [NotePar] AS Expr5, [Z3Par] AS Expr6, [Z5Par] AS Expr7, 
       [FollowupNotesPar] AS Expr10;

Here is my VBA code tied to a save button on my form:

Private Sub cmdSaveandNew_Click()

Dim db As DAO.Database
Dim qdf1 As DAO.QueryDef

Set db = CurrentDb
Set qdf1 = db.QueryDefs("qryInsertLog")

'put form parameters into insert query
qdf1.Parameters(0).Value = Me.cboUser.Value
qdf1.Parameters(1).Value = Me.cboApprover.Value
qdf1.Parameters(2).Value = Me.cboCCer.Value
qdf1.Parameters(3).Value = Me.cboUnit.Value
qdf1.Parameters(4).Value = Me.txtNotes.Value
qdf1.Parameters(5).Value = Me.chkZ3.Value
qdf1.Parameters(6).Value = Me.chkz5.Value
qdf1.Parameters(7).Value = Me.txtFollowup.Value

qdf1.Execute

Set qdf1 = Nothing
Call resetForm

End Sub

"resetForm" is a routine that simply returns the form controls to their default values.

When I hit my save button, sometimes the record gets added, but without getting the correct values for Me.chkZ3.Value and Me.chkZ5.Value (meaning if I had them checked, the record gets entered with those values as false). After hitting the save button a few times, I start getting the following error:

Run-time error '3000':

Reserved error (-3033); there is no message for this error.

The most interesting part about this, however, is that when I modify my query to only include 1 yes/no field, I get no errors and records are updated correctly.

What the heck is going on here?

edit: I forgot to mention that when I run the query from the Access Objects window (as opposed to VBA), it works exactly as it should.

回答1:

The problem are the LongText parameters. I tried a similar query:

PARAMETERS pText1 Text ( 255 ), pInt1 Short, pMemo1 LongText, pYesno1 Bit, pYesno2 Bit;
INSERT INTO ForInsert ( text1, int1, Memo1, yesno1, yesno2 )
SELECT [pText1] AS A1, [pInt1] AS A2, [pMemo1] AS A3, [pYesno1] AS A4, [pYesno2] AS A5;

with this code

Set db = CurrentDb
Set qdf1 = db.QueryDefs("qAppForInsert")

qdf1.Parameters(0).Value = "asdf"
qdf1.Parameters(1).Value = 77
qdf1.Parameters(2).Value = String(3, "a")
qdf1.Parameters(3).Value = True
qdf1.Parameters(4).Value = False

qdf1.Execute

and various length for the LongText parameter (2, 10, 3) .

Resulting in this crazy data (the Yes/No fields were always yesno1 = True and yesno2 = False !) :

+----+-------+------+------------+--------+--------+
| ID | text1 | int1 |   Memo1    | yesno1 | yesno2 |
+----+-------+------+------------+--------+--------+
|  8 | asdf  |   77 | aa         | True   | False  |
|  9 | asdf  |   77 | aaaaaaaaaa | False  | False  |
| 10 | asdf  |   77 | aaa        | False  | True   |
+----+-------+------+------------+--------+--------+

So apparently with LongText parameters, you are better off using RecordSet.AddNew instead of a parameterized query.

Parameters are limited to 255 characters anyway.

Addendum

If I run the code in a loop to find a system, I also get the Reserved error (-3033).

回答2:

You should probably add a bunch more error tracking and checking for Null values in your form fields before assigning them to your table. Saying that, this one fix might fix your immediate problem.

I assume your Z3 and Z5 fields are bit fields - seeing as that's how you declared the matching parameter types.

If that's so, you should probably trap for Null checkboxes and convert true(-1) to 1

' Set to 0 if checkbox is Null, Set to 1 if checked=true
' Bit fields can't take -1 values
qdf1.Parameters(5).Value = IIf(Nz(Me.chkZ3.Value, 0), 1, 0)
qdf1.Parameters(6).Value = IIf(Nz(Me.chkz5.Value, 0), 1, 0)

As a sidenote, I would also suggesting using named parameters instead of numeric indexes in case the order of those ever get changed - and also for readability and future maintenance ease

Instead of

qdf1.Parameters(0).Value = Me.cboUser.Value

Use

qdf1.Parameters("UserPar").Value = Me.cboUser.Value

来源：https://stackoverflow.com/questions/39106471/ms-access-2013-calling-insert-queries-from-vba-with-strange-errors

标签

ms-access

access-vba

ms-access-2013