Gradle DSL error not found mavenCentral()

问题

I have tried to add some dependencies to my project but i kepp getting this error:

    Error:(21, 0) Gradle DSL method not found: 'mavenCentral()'
Possible causes:<ul><li>The project 'My Application' may be using a version of Gradle that does not contain the method.
<a href="open.wrapper.file">Open Gradle wrapper file</a></li><li>The build file may be missing a Gradle plugin.
<a href="apply.gradle.plugin">Apply Gradle plugin</a></li>

I have tried everything to solve it. here are my gradle files:

    // Top-level build file where you can add configuration options common to all sub-projects/modules.

buildscript {
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:2.1.0'

        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

allprojects {
    repositories {
        mavenCentral()

    }

    mavenCentral()
    maven {
        url "http://indooratlas-ltd.bintray.com/mvn-public"
    }
}

and this is the other one:

    apply plugin: 'com.android.application'

android {
    compileSdkVersion 23
    buildToolsVersion "23.0.2"
    def apiKey = project.properties['indoorAtlasApiKey'] ?: "api-key-not-set";
    def apiSecret = project.properties['indoorAtlasApiSecret'] ?: "api-secret-not-set";
    def pubNubPublishKey = project.properties['pubNubPublishKey'] ?: "not-set";
    def pubNubSubscribeKey = project.properties['pubNubSubscribeKey'] ?: "not-set";

    defaultConfig {
        applicationId "io.noxel.showroom"
        minSdkVersion 19
        targetSdkVersion 23
        versionCode 1
        versionName "1.0"
        resValue "string", "indooratlas_api_key", apiKey
        resValue "string", "indooratlas_api_secret", apiSecret.replaceAll("%", "\\\\u0025")
        resValue "string", "pubnub_publish_key", pubNubPublishKey
        resValue "string", "pubnub_subscribe_key", pubNubSubscribeKey
    }
    buildTypes {
        release {
            signingConfig signingConfigs.debug
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
        debug {
            debuggable true
        }
        lintOptions {
            abortOnError false
        }
    }
}

dependencies {
    compile fileTree(dir: 'libs', include: ['*.jar'])
    compile 'com.indooratlas.android:indooratlas-android-sdk:2.2.0@aar'
    compile 'com.android.support:appcompat-v7:23.1.0'
    compile 'com.google.android.gms:play-services:8.4.0'
    compile 'com.google.maps.android:android-maps-utils:0.3.+'
    compile 'com.squareup.picasso:picasso:2.5.2'
    compile 'com.davemorrissey.labs:subsampling-scale-image-view:3.2.0'
    compile 'com.pubnub:pubnub-android:3.7.5'
    compile 'com.android.support:design:24.0.0-alpha2'
}

can anyone tell me how to solve it?

回答1:

this:

allprojects {
    repositories {
        mavenCentral()

    }

    mavenCentral()
    maven {
        url "http://indooratlas-ltd.bintray.com/mvn-public"
    }
}

has to be changed to:

allprojects {
    repositories {
        mavenCentral()
        maven {
          url "http://indooratlas-ltd.bintray.com/mvn-public"
       } 
    }
}

回答2:

Dont add mavenCentral() twice remove one which is outside the repositories tag.

    allprojects {
        repositories {
        mavenCentral()
        maven {
            url "http://indooratlas-ltd.bintray.com/mvn-public"
          }
        }
     }

来源：https://stackoverflow.com/questions/39063265/gradle-dsl-error-not-found-mavencentral