Duplicate declaration of same resource defined in separate classes

问题

I have a class definition which requires the build-essential package:

class erlang($version = '17.3') {

  package { "build-essential": 
    ensure => installed
  }
  ...
}

Another class in a different module also requires the build-essential package:

class icu {

  package { "build-essential": 
    ensure => installed
  }
  ...
}

However, when I try to perform puppet apply, the error I receive is:

Error: Duplicate declaration: Package[build-essential] is already declared in file /vagrant/modules/erlang/manifests/init.pp:18; cannot redeclare at /vagrant/modules/libicu/manifests/init.pp:17 on node vagrant-ubuntu-trusty-64.home

I was expecting classes to encapsulate the resources they use but this doesn't seem to be the case? How can I resolve this clash?

回答1:

This is common question when dealing with multiple modules.

There's a number of ways of doing this, the best practise is to modularise and allow the installation of build essential as a parameter:

class icu ($manage_buildessential = false){

  if ($manage_buildessential == true) {
   package { "build-essential": 
     ensure => installed
   }
 }
}

Then, where you want to include your ICU class:

class {'icu':
   manage_buildessential => 'false',
}

However, for a quick and dirty fix:

if ! defined(Package['build-essential']) {
    package { 'build-essential': ensure => installed }
}

Or if you have puppetlabs-stdlib module:

ensure_packages('build-essential')

回答2:

If you control both modules, you should write a third class (module) to manage the shared resource.

class build_essential {
    package { 'build-essential': ensure => installed }
}

Contexts that require the package just

include build_essential

Do not touch the defined() function with a 12" pole. There can be only pain down this road.

回答3:

There are multiple ways as the other answers explain but this is another reliable way of doing it if you want to use the same resource multiple times.

Declare once and then realize it multiple times.. For example, Create a new virtual resource like this:

in modules/packages/manifests/init.pp

class packages {
  @package{ 'build-essential':
    ensure => installed
  }
}

Then, in your both classes, include the below lines to realize the above virtual resource

include packages
realize Package('build-essential')

来源：https://stackoverflow.com/questions/26205727/duplicate-declaration-of-same-resource-defined-in-separate-classes

标签

puppet