A quick way to repeatedly enter a variable name in Emacs?

Question

I was just typing in this sort of code for Nth time:

menu.add_item(spamspamspam, "spamspamspam");

And I'm wondering if there's a faster way to do it.

I'd like a behavior similar to yasnippet's mirrors, except I don't want to create a snippet: the argument order varies from project to project and from language to language.

The only thing that's constant is the variable name that needs to be repeated several times on the same line.

I'd like to type in

menu.add_item($,"")

and with the point between the quotes, call the shortcut and start typing, and finally exit with C-e.

This seems advantageous to me, since there's zero extra cursor movement. I have an idea of how to do this, but I'm wondering if it's already done, or if something better/faster can be done.

UPD The yasnippet way after all.

Thanks to thisirs for the answer. This is indeed the yasnippet code I had initially in mind:

(defun yas-one-line ()
  (interactive)
  (insert "$")
  (let ((snippet 
         (replace-regexp-in-string 
          "\\$" "$1"
          (substring-no-properties
           (delete-and-extract-region
            (line-beginning-position)
            (line-end-position))))))
    (yas/expand-snippet snippet)))

But I'm still hoping to see something better/faster.

Answer 1

yasnippet can actually be used to create a snippet on-the-fly:

(defun yas-one-line ()
  (interactive)
  (let ((snippet (delete-and-extract-region
                  (line-beginning-position)
                  (line-end-position))))
    (yas-expand-snippet snippet)))

Now just type:

menu.add_item($1,"$1")

and call yas-one-line. The above snippet is expanded by yasnippet!

Answer 2

You could try

(defvar sm-push-id-last nil)
(defun sm-push-id ()
  (interactive)
  (if (not sm-push-id-last)
      (setq sm-push-id-last (point))
    (text-clone-create sm-push-id-last sm-push-id-last
                       t "\\(?:\\sw\\|\\s_\\)*")
    (setq sm-push-id-last nil)))

after which you can do M-x sm-push-id RET , SPC M-x sm-push-id RET toto and that will insert toto, toto. Obviously, this would make more sense if you bind sm-push-id to a convenient key-combo. Also this only works to insert a duplicate pair of identifiers. If you need to insert something else, you'll have to adjust the regexp. Using too lax a regexp means that the clones will tend to overgrow their intended use, so they may become annoying (e.g. you type foo") and not only foo but also ") gets mirrored on the previous copy).

Answer 3

Record a macro. Hit F3 (or possibly C-x (, it depends) to begin recording. Type whatever you want and run whatever commands you need, then hit F4 (or C-x )) to finish. Then hit F4 again the next time you want to run the macro. See chapter 17 of the Emacs manual for more information (C-h i opens the info browser, the Emacs manual is right at the top of the list).

So, for example, you could type the beginning of the line:

menu.add_item(spamspamspam

Then, with point at the end of that line, record this macro:

F3 C-SPC C-left M-w C-e , SPC " C-y " ) ; RET F4

This copies the last word on the line and pastes it back in, but inside of the quotes.