Issues writing to file in assembly

Question

I am trying to write a simple program in assembly in which I open an existing file and I write a message in it, a message which I define in my data segment. The problem occurs when I want to write to my file. The AX register will contain 5 after I try writing to it, and the Norton Expert Guide says that is an 'Access denied' error code. Any ideas on what I'm doing wrong? Sorry if this question is pretty easy, I'm just trying to learn some assembly for an upcoming test. I am using TASM to compile my code. The file in which I want to write exists(hence the no error when I open it) and it's empty.

Here is my code:

assume cs:code, ds:data
data segment
    errorMsg db 'Error at opening $'
    errorMsg2 db 'Error at writing $'
    msg db 'File name: $'
    maxFile db 12
    fileLength db ?
    fileName db 12 dup(?)
    buffer db 100, '$'
    text db "Here $"
    handle dw ?

data ends
code segment
start:
    mov ax, data
    mov ds, ax

    ;print 'File name: ' message on screen
    mov ah, 09h
    mov dx, offset msg
    int 21h

    ;enter name of file
    mov ah, 0ah
    mov dx, offset maxFile
    int 21h

    ; transform file name in an asciiz string which ends in 0
    mov al, fileLength
    xor ah, ah
    mov si, ax
    mov fileName[si], 0

    ;open file
    mov ah,3dh
    mov al, 0
    mov dx, offset fileName
    int 21h
    mov handle, ax; saving the file handle

    jc openError;jump if carry, will print 'error at opening'


    ;write in file
    mov ah, 40h
    mov bx, handle
    mov cx, 4 ;number of bytes to write
    mov dx, offset text
    int 21h

    jc openError2 ;jump if carry, will print 'error at writing'
    ;!!! here is where I get the error, my program jumps to openError2 label!!!;

    ;close file
    mov ah, 3eh
    mov bx, handle
    int 21h

    jmp endPrg;jump over errors if it reached this point

    openError:
        mov ah, 09h
        mov dx, offset errorMsg
        int 21h

    openError2:
        mov ah, 09h
        mov dx, offset errorMsg2
        int 21h

    endPrg:
        mov ax,4c00h
        int 21h
code ends
end start

Answer 1

Alright, sorry for this question actually, but I finally figured it out. When I opened the file, I did

mov al, 0

which means I opened the file with read-only access. What I needed to do was

mov al, 1 (write-only access) or 
mov al, 2 (read+write access). 

Sorry for the bother guys, I'm just glad I finally figured it out.