Perl hash substitution with special characters in keys

Question

My current script will take an expression, ex:

my $expression = '( a || b || c )';

and go through each boolean combination of inputs using sub/replace, like so:

my $keys = join '|', keys %stimhash;
$expression =~ s/($keys)\b/$stimhash{$1}/g;

So for example expression may hold,

( 0 || 1 || 0 )

This works great.

However, I would like to allow the variables (also in %stimhash) to contain a tag, *.

my $expression = '( a* || b* || c* )';

Also, printing the keys of the stimhash returns:

a*|b*|c*

It is not properly substituting/replacing with the extra special character, *.
It gives this warning:

Use of uninitialized value within %stimhash in substitution iterator

I tried using quotemeta() but did not have good results so far.
It will drop the values. An example after the substitution looks like:

( * || * || * )

Any suggestions are appreciated,

John

Answer 1

Problem 1

You use the pattern a* thinking it will match only a*, but a* means "0 or more a". You can use quotemeta to convert text into a regex pattern that matches that text.

Replace

my $keys = join '|', keys %stimhash;

with

my $keys = join '|', map quotemeta, keys %stimhash;

Problem 2

\b

is basically

(?<!\w)(?=\w)|(?<=\w)(?!\w)

But * (like the space) isn't a word character. The solution might be to replace

s/($keys)\b/$stimhash{$1}/g

with

s/($keys)(?![\w*])/$stimhash{$1}/g

though the following make more sense to me

s/(?<![\w*])($keys)(?![\w*])/$stimhash{$1}/g

Personally, I'd use

s{([\w*]+)}{ $stimhash{$1} // $1 }eg