Pattern matching equality on tuples in Haskell

问题

For this function on symmetric equality over tuples,

symEq :: Eq a => (a,a) -> (a,a) -> Bool
symEq (x,y) (u,v) = (x,y) == (u,v) || (x,y) == (v,u)

would like to rewrite it using pattern matching as follows,

symEq' :: Eq a => (a,a) -> (a,a) -> Bool
symEq' (x,y) (x,y) = True
symEq' (x,y) (y,x) = True
symEq' _ _ = False

The latter fails with error on conflicting definitions for x and y. How to rewrite symEq and take benefit of pattern matching ?

回答1:

Unlike in some languages (I hear Erlang works that way), repeating a variable name in patterns in Haskell does not compare the values found at those two places, and is usually an error. So you are going to need to use == for that.

Anyway, here is a slightly more concise way of writing your function:

symEq t (x,y) = t == (x,y) || t == (y,x)

Or even

symEq t (x,y) = t `elem` [(x,y), (y,x)]

回答2:

With the ViewPatterns you can achieve something that resembles the Erlang and Prolog pattern matching style:

{-# LANGUAGE ViewPatterns #-}

swap (a,b) = (b,a)

symEq :: Eq a => (a,a) -> (a,a) -> Bool
symEq a ((==a) -> True) = True
symEq a ((==a).swap -> True) = True
symEq _ _ = False

Note how the a in (==a) refers to the first function argument - bound names of earlier function parameters may be used in the view patterns of later parameters.

More details on ViewPatterns may be found here.

来源：https://stackoverflow.com/questions/26601923/pattern-matching-equality-on-tuples-in-haskell